Updated c_intercal-28.0.28.ebuild

c_intercal-28.0.28.ebuild (text/plain), 1.15 KB, created by Arvid Norlander on 2008-06-20 16:33:47 UTC

# Copyright 2008 Arvid Norlander
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit eutils multilib versionator

# Yes, C-INTERCAL uses minor-major...
MY_PV=$(get_version_component_range 2-3)

DESCRIPTION="C-INTERCAL - INTERCAL to binary (via C) compiler"
HOMEPAGE="http://intercal.freeshell.org"
SRC_URI="http://intercal.freeshell.org/download/ick-${MY_PV/./-}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE=""

DEPEND="sys-devel/gcc"
RDEPEND="${DEPEND}"

S=${WORKDIR}/ick-${MY_PV}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-fix-install-info.patch || die "epatch failed"
	epatch "${FILESDIR}"/${P}-fix-64bit.patch || die "epatch failed"
}

src_compile() {
	# This was done for DOS compatiblity it seems.
	# Go figure...
	cd "${S}" || die "cd to ${S} failed"
	ln -s config.sh configure || die "ln -s failed"
	econf || die "econf failed"
	emake -j1 || die "make failed"
}

src_install() {
	# Thinks the directories exist, won't as this is done to a DESTDIR...
	dodir /usr/bin
	dodir /usr/$(get_libdir)
	emake -j1 DESTDIR="${D}" install || die "make install failed"
}