ebuild for basiliskII-1.0_pre20060501

basiliskII-1.0_pre20060501.ebuild (text/plain), 2.82 KB, created by Eric "me262" Mason on 2008-06-17 08:52:49 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic eutils

S="${WORKDIR}/BasiliskII-1.0/src/Unix"
DESCRIPTION="Basilisk II Macintosh Emulator"
HOMEPAGE="http://gwenole.beauchesne.info/projects/basilisk2/"
SRC_URI="http://gwenole.beauchesne.info/projects/basilisk2/files/BasiliskII_src_01052006.tar.bz2"

LICENSE="|| ( GPL-2 LGPL-2.1 )"
KEYWORDS="~x86 -ppc"
SLOT="0"

IUSE="dga esd fbdev gtk jit nls sdl xv"

RDEPEND="esd? ( media-sound/esound )
	!sdl? ( fbdev? ( x11-drivers/xf86-video-fbdev ) )
	gtk? ( >=x11-libs/gtk+-1.3.15 gnome-base/libgnomeui )
	!sdl? ( dga? ( x11-libs/libXxf86dga ) )
	sdl? ( media-libs/libsdl )
	nls? ( virtual/libintl )
	x11-libs/libSM
	x11-libs/libXi
	x11-libs/libXxf86vm
	!app-emulation/basiliskII-jit"

DEPEND="${RDEPEND}
	!sdl? ( dga? ( x11-proto/xf86dgaproto ) )
	nls? ( sys-devel/gettext )
	x11-proto/xf86vidmodeproto
	x11-proto/xextproto
	x11-proto/xproto
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}

	# Fix up the vendor (bug 35352)
	sed -i \
		-e "s/Mandrake/Gentoo/g" ${S}/keycodes || \
			die "sed keycodes failed"

	#prevent prestripped binary
	cd "${S}"
	sed -i -e '/^INSTALL_PROGRAM/s/-s//' Makefile.in

	if ( use sdl && ( use fbdev || use dga ) ) ; then
		elog "SDL support was requested, disabling DGA and fbdev"
	elif ( use dga && use fbdev ) ; then
		elog "DGA support was requested, disabling fbdev"
	fi
}

src_compile() {
	#fpu_x86 doesnt compile properly if -O3 or greater :(
	replace-flags -O[3-9] -O2

	local myflags

### Most default ./configure options are all =yes by default. we'll
### check for and use -values and switch them accordingly

	use esd || myflags="${myflags} --with-esd=no"
	use gtk || myflags="${myflags} --with-gtk=no"
	use dga || myflags="${myflags} --enable-xf86-dga=no"
	use jit && myflags="${myflags} --enable-jit-compiler"
	use fbdev || myflags="${myflags} --enable-fbdev-dga=no"
	use nls || myflags="${myflags} --disable-nls"
	use sdl && myflags="${myflags} \
		--enable-sdl-video=yes \
		--enable-sdl-audio=yes"
	use xv || myflags="${myflags} --enable-xf86-vidmode=no"

	./configure \
		--host=${CHOST} \
		--prefix=/usr \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man \
		${myflags} || die "./configure failed"

	emake -j1 || die "emake failed"

}

src_install() {
	make \
		prefix=${D}/usr \
		mandir=${D}/usr/share/man \
		infodir=${D}/usr/share/info \
		install || die "make install failed"

	cd ../..
	dodoc ChangeLog README TECH TODO
}

pkg_postinst() {	
	einfo ""
	einfo "Please read the README doc file for information on networking"
	einfo "in Basilisk II."
	einfo ""
	einfo "Basilisk II requires a Mac II or Mac Classic ROM to work."
	einfo ""
	einfo "Mac OS 7.5.3r2 is available freely from the Apple Homepage."
	einfo ""
	einfo "System ROMs can be retreived from a real Mac, see info/man pages."
}