# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/tunepimp/tunepimp-0.5.3-r1.ebuild,v 1.3 2008/04/07 05:49:25 philantrop Exp $

WANT_AUTOCONF="2.5"
WANT_AUTOMAKE="latest"

EAPI="1"


inherit eutils distutils autotools flag-o-matic

MY_P="lib${P}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="TunePimp is a library to create MusicBrainz enabled tagging applications."
HOMEPAGE="http://www.musicbrainz.org/products/tunepimp"
SRC_URI="http://ftp.musicbrainz.org/pub/musicbrainz/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
# Most use flags were void as not deterministic - needs a patch sooner or later.
#IUSE="flac mp3 readline perl python vorbis"
IUSE="python perl flac mp3 vorbis wma mp4 mpc speex tta wv"

RDEPEND="sys-libs/zlib
	dev-libs/expat
	net-misc/curl
	>=media-libs/flac-1.1.2
	media-libs/libmad
	>=media-libs/musicbrainz-2.1.0:1
	media-libs/libofa
	media-libs/libvorbis
	!media-sound/trm
	sys-libs/readline"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

# parallel build is broken - https://bugs.gentoo.org/204174
MAKEOPTS="${MAKEOPTS} -j1"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${P}-gcc43.patch"
	epatch "${FILESDIR}/${P}-plugin.diff"
	epatch "${FILESDIR}/${P}-configure.patch"

	sed -i -e "s: tta::" ${S}/configure.in 
	sed -i -e 's/lt_dlhandle_struct \*/lt_dlhandle/' ${S}/lib/plugins.cpp 

	#Added ${S}/libltdl - http://bugs.gentoo.org/show_bug.cgi?id=220565 
	eautoreconf ${S}/libltdl
}

src_compile() {
	# We need to override distutils_src_compile, bug 160145
	
	strip-flags && append-flags -D_GNU_SOURCE
	
	econf \
	--enable-ltdl-install=no \
	$(use_with mp3) \
	$(use_with flac) \
	$(use_with mp4) \
	$(use_with mpc) \
	$(use_with vorbis) \
	$(use_with speex) \
	$(use_with tta) \
	$(use_with wma) \
	$(use_with wv) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog INSTALL README TODO || die "installing docs failed"

	if use python; then
		cd "${S}/python"
		insinto /usr/share/doc/${P}/examples/
		doins -r examples/* || die "installing python examples failed"
	fi

	if use perl; then
		cd "${S}/perl/tunepimp-perl"
		insinto /usr/share/doc/${P}/examples/
		doins -r examples/* || die "installing perl examples failed"
	fi
}