# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs flag-o-matic eutils

DESCRIPTION="A high-performance, portable C++ Library for doing Number Theory"
HOMEPAGE="http://shoup.net/ntl/"
SRC_URI="http://www.shoup.net/ntl/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~ppc64"
IUSE="doc gmp shared"

RDEPEND=">=dev-libs/gmp-4.1-r1"
DEPEND="${RDEPEND}
	dev-lang/perl"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# patch to enable compatibility with singular
	epatch "$FILESDIR"/sage-new.h.patch
	# patch to implement a call back framework ( submitted upstream)
	epatch "$FILESDIR"/sage-tools.patch

	use shared && epatch "$FILESDIR/${P}-mfile.patch"
}

src_compile() {
	local myconf=""
	use gmp && myconf="${myconf} NTL_GMP_LIP=on"
	cd "${S}/src"
	perl DoConfig \
		PREFIX=/usr \
		${myconf} \
		CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" LDFLAGS="${LDFLAGS}" \
		CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
		AR="$(tc-getAR)" RANLIB="$(tc-getRANLIB)" \
		NTL_STD_CXX=on \
		|| die "DoConfig failed"

	emake || die "emake failed"

	use shared && (emake libntl.so || die "emake failed")
}

src_install() {
	newlib.a src/ntl.a libntl.a 
	if use shared ; then
		dolib.so src/lib"${P}".so
		dosym lib"${P}".so /usr/lib/lib"${PN}".so
	fi
	insinto /usr/include
	doins -r include/NTL

	dodoc README

	if use doc ; then
		dodoc doc/*.txt
		dohtml doc/*.{html,gif}
	fi
}

src_test() {
	cd src
	emake check || die "emake check failed"
}