# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit cmake-utils eutils qt4

QT4_BUILT_WITH_USE_CHECK="dbus ssl"

DESCRIPTION="Qt4-based download/upload manager"
HOMEPAGE="http://fatrat.dolezel.info/"
SRC_URI="http://www.dolezel.info/download/data/${PN}/${P}.tar.bz2"

KEYWORDS="~x86 ~amd64"
IUSE="+bittorrent doc -debug jabber nls sftp"
LICENSE="GPL-2"
SLOT="0"

DEPEND="$(qt4_min_version 4.3.0)
    bittorrent? ( >=net-libs/rb_libtorrent-0.13 )
    doc? ( x11-libs/qt-assistant:4 )
    jabber? ( <net-libs/gloox-1.0_beta1 )
    sftp? ( net-libs/libssh2 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

pkg_setup() {
	qt4_pkg_setup
	# this is completely optional and NOT automagic dep
	# (it is dynamically loaded)
	if ! has_version dev-libs/geoip; then
		einfo "If you want the GeoIP support, then emerge dev-libs/geoip."
	fi
}

src_compile() {
	local myconf=""
	use debug && myconf="-DCMAKE_BUILD_TYPE=Debug"
	cmake . \
		-DCMAKE_INSTALL_PREFIX="/usr" \
		$(cmake-utils_use_with bittorrent BITTORRENT) \
		$(cmake-utils_use_with doc DOCUMENTATION) \
		$(cmake-utils_use_with jabber JABBER) \
		$(cmake-utils_use_with nls NLS) \
		$(cmake-utils_use_with sftp SFTP) \
		${myconf}
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
}