Ada Web Server ebuild

aws-2.3.0.ebuild (text/plain), 2.74 KB, created by gentoo on 2008-04-29 22:22:57 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnat versionator

IUSE="xml asis ssl gnutls ipv6"

DESCRIPTION="A complete Web development framework" 
HOMEPAGE="http://libre.adacore.com/aws/"
SRC_URI="http://libre.adacore.com/aws/aws-gpl-${PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

DEPEND="virtual/ada
net-nds/openldap
dev-libs/openssl
xml? (dev-ada/xmlada)"

S="${WORKDIR}/AWS-gpl-${PV}"

src_unpack() {
	unpack ${A}

	cd ${S}

	sed -i -e "s:\"\.\./\.\./\.\./include/aws/components\": :" \
		config/projects/aws_components.gpr || die "failed to adjust project files"

	sed -i -e "s:\.\./\.\./\.\./include/aws:${AdalibSpecsDir}/${PN}:" \
		config/projects/*.gpr || die "failed to adjust project files"

	sed -i -e "s:\.\./\.\./include/aws:${AdalibSpecsDir}/${PN}:" \
		config/projects/*.gpr || die "failed to adjust project files"

	# Fix wrong use of tail
	sed -i -e "s|tail|tail -n|" \
		templates_parser/docs/makefile

	sed -i -e "s|CFLAGS =|CFLAGS = -fPIC |" \
		include/zlib/makefile

	mv templates_parser/src/templates_parser.adb templates_parser/src/templates_parser.adb~
	echo "with Ada.Text_IO;" > templates_parser/src/templates_parser.adb
	cat templates_parser/src/templates_parser.adb~ >> templates_parser/src/templates_parser.adb
	rm templates_parser/src/templates_parser.adb~

	mv xsrc/aws-jabber.adb xsrc/aws-jabber.adb~
	echo "with Ada.Exceptions;" > xsrc/aws-jabber.adb
	cat xsrc/aws-jabber.adb~ >> xsrc/aws-jabber.adb
	rm xsrc/aws-jabber.adb~
}

lib_compile () {
	local myconf

	myconf="EXTRA_MODULES= SHARED=true"

	if use ssl ; then
		myconf="${myconf} SOCKET=openssl"
	elif use gnutls ; then
		myconf="${myconf} SOCKET=gnutls"
	fi
	if use xml ; then
		myconf="${myconf} XMLADA=true"
	fi
	if use asis ; then
		myconf="${myconf} AISIS=true"
	fi
	if use ipv6 ; then
		myconf="${myconf} IPv6=true"
	fi

	emake setup ${myconf} build -j1
}

lib_install () {
	make INSTALL="${DL}" install
	pushd "${DL}"
		mv lib/aws/* .

		sed -i -e "s:\.\./\.\./lib/aws:${AdalibLibTop}/$1/${PN}:" "${DL}"/lib/gnat/*.gpr

		sed -i -e "s:\.\./\.\./\.\./lib/aws:${AdalibLibTop}/$1/${PN}:" "${DL}"/lib/gnat/aws/*.gpr

		mv lib/gnat/* "${DLgpr}"
		rm -rf bin include lib share
	popd
}

src_install ()
{
	cd "${S}"
	dodir ${AdalibSpecsDir}/${PN}
	insinto ${AdalibSpecsDir}/${PN}
	doins include/*.ad? src/*.ad? ssl/*.ad? config/*.ad?

	if use xml ; then
		doins xsrc/*.ad?
	fi

	dodoc AUTHORS COPYING readme.txt docs/aws.pdf docs/aws.ps docs/aws.txt docs/TODO

	#set up environment
	echo "PATH=%DLbin%" > ${LibEnv}
	echo "LDPATH=%DL%" >> ${LibEnv}
	echo "ADA_OBJECTS_PATH=%DL%" >> ${LibEnv}
	echo "ADA_INCLUDE_PATH=${AdalibSpecsDir}/${PN}" >> ${LibEnv}
	echo "ADA_PROJECT_PATH=%DLgpr%" >> ${LibEnv}

	gnat_src_install
}