# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs

MY_P=mumble-${PV}
EAPI=1

DESCRIPTION="Voice chat software for gaming written in Qt4 (server)"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="mirror://sourceforge/mumble/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="logrotate mysql pch +sqlite"

RDEPEND="=x11-libs/qt-4*
	logrotate? ( app-admin/logrotate )"

DEPEND="=x11-libs/qt-4*
	dev-util/pkgconfig"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	if ! use sqlite && ! use mysql ; then
		eerror "You need either sqlite or mysql for a database backend"
		die "No database selected"
	fi
	if use sqlite ; then
		if ! built_with_use =x11-libs/qt-4* sqlite3 ; then
			echo
			ewarn "You need to build Qt4 with the sqlite3 use flag"
			echo
			die "Your Qt4 has no sqlite support"
		fi
	fi
	if use mysql ; then
		if ! built_with_use =x11-libs/qt-4* mysql ; then
			echo
			ewarn "You need to build Qt4 with the mysql use flag"
			echo
			die "Your Qt4 has no mysql support"
		fi
	fi
	if ! built_with_use -a =x11-libs/qt-4* dbus zlib ssl; then
		echo
		ewarn "You need to build Qt4 with DBus, ssl and zlib use flag"
		echo
		die "Your Qt4 has no dbus and/or ssl and/or zlib support"
	fi
	enewgroup murmur
	enewuser murmur -1 -1 /var/lib/murmur murmur
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e 's:mumble-server:murmur:' scripts/murmur.conf
	sed -i -e 's:/var/lib/mumble-server/mumble-server.sqlite:/var/lib/murmur/murmur.sqlite:' scripts/murmur.ini.system
	sed -i -e 's:/var/run/mumble-server/mumble-server.pid:/var/run/murmur.pid:' scripts/murmur.ini.system
	sed -i -e 's:/var/run/mumble-server/mumble-server.pid:/var/run/murmur.pid:' scripts/murmur.logrotate
	sed -i -e 's:/var/log/mumble-server/mumble-server.log:/var/log/murmur.log:' scripts/murmur.ini.system
	sed -i -e 's:/var/log/mumble-server/mumble-server.log:/var/log/murmur.log:' scripts/murmur.logrotate
	sed -i -e 's:--user mumble-server:--user murmur:' scripts/murmur.logrotate
	use pch || sed -i -e 's: precompile_header::' src/mumble.pri
}

src_compile() {
	cd src/murmur
	qmake murmur.pro 	|| die "qmake failed"
	emake CC="$(tc-getCC) ${CFLAGS}" \
		CXX="$(tc-getCXX) ${CXXFLAGS}" \
		LINK="$(tc-getCXX)" || die "emake failed"
}

src_install() {
	dobin release/murmurd || die "installing failed"
	dodoc README CHANGES || die "installing docs failed"
	docinto scripts ; dodoc scripts/*
	insinto /etc/murmur
	newins scripts/murmur.ini.system murmur.ini
	newinitd "${FILESDIR}"/murmurd.rc murmur
	newconfd "${FILESDIR}"/murmur.confd murmur

	if use logrotate; then
		insinto /etc/logrotate.d
		newins scripts/murmur.logrotate murmur
	fi

	insinto /etc/dbus-1/system.d
	doins scripts/murmur.conf
	
	dodir /var/lib/murmur
	fowners -R murmur:murmur /var/lib/murmur
	fperms 750 /var/lib/murmur
	keepdir /var/lib/murmur

	doman man/murmur-wrapper.1
	doman man/murmurd.1
}

pkg_postinst() {
	elog "Useful scripts are located in /usr/share/doc/murmur-${PV}/scipts."
	elog "Please execute: murmurd -ini /etc/murmur/murmur.ini -supw <pw>"
	elog "to set the inbuild 'SuperUser' password before starting murmur."
	elog "And then run: chown -R murmur:murmur /var/lib/murmur"
	elog "or /etc/init.d/murmur will not be able to work correctly."
}