opencd-9999.ebuild

opencd-9999.ebuild (text/plain), 1.38 KB, created by SpanKY on 2008-04-14 01:00:16 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

ESVN_REPO_URI="http://svn.berlios.de/svnroot/repos/openocd/trunk"
inherit eutils subversion

DESCRIPTION="OpenOCD - Open On-Chip Debugger"
HOMEPAGE="http://openocd.berlios.de/web/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="+ft2232 +presto libftdi parport_giveio"

S="${WORKDIR}/trunk"

# libftd2xx is the default because it is reported to work better.
DEPEND="presto? ( dev-embedded/libftd2xx )
	ft2232? ( || ( libftdi? ( dev-embedded/libftdi ) dev-embedded/libftd2xx ) )"

pkg_setup() {
	if use libftdi && ! use ft2232 ; then
		ewarn "You enabled libftdi but not ft2232!"
		ewarn "libftdi is only used for ft2232, so this is meaningless!"
	fi
}

src_unpack() {
	subversion_src_unpack
	cd "${S}"
	./bootstrap || die "Can't bootstrap!"
}

src_compile() {
	econf \
		--enable-parport \
		--enable-parport_ppdev \
		--enable-amtjtagaccel \
		--enable-ep93xx \
		--enable-at91rm9200 \
		--enable-gw16012 \
		--enable-usbprog \
		--enable-oocd_trace \
		$(use_enable parport_giveio) \
		$(use_enable presto presto_ftd2xx) \
		$(use ft2232 && use_enable libftdi ft2232_libftdi) \
		$(use ft2232 && use_enable !libftdi ft2232_ftd2xx) \
		|| die "Error in econf!"
	emake || die "Error in emake!"
}

src_install() {
	cd build
	emake DESTDIR="${D}" install || die
}