frozen-bubble-1.0.0-r2.ebuild

frozen-bubble-1.0.0-r2.ebuild (text/plain), 1.67 KB, created by TGL on 2003-07-23 17:26:05 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/app-games/frozen-bubble/frozen-bubble-1.0.0-r2.ebuild,v 1.3 2003/07/22 18:18:44 wolf31o2 Exp $

inherit games perl-module

NET_CLIENT_P=frozen-bubble-client-0.0.3
NET_SERVER_P=frozen-bubble-server-0.0.3
DESCRIPTION="A Puzzle Bubble clone written in perl (now with network support)"
HOMEPAGE="http://www.frozen-bubble.org/ http://chl.tuxfamily.org/frozen-bubble/"
SRC_URI="http://guillaume.cottenceau.free.fr/fb/${P}.tar.bz2
	http://chl.tuxfamily.org/frozen-bubble/${NET_CLIENT_P}.tar.bz2
	http://chl.tuxfamily.org/frozen-bubble/${NET_SERVER_P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~ppc"
IUSE=""

DEPEND="virtual/glibc
	>=sys-apps/sed-4
	>=dev-lang/perl-5.6.1
	>=media-libs/sdl-mixer-1.2.3
	>=dev-perl/sdl-perl-1.19.0"

src_unpack() {
	unpack ${A}

	sed -i -e 's:INSTALLDIRS=.*:PREFIX=${D}/usr:' \
		${P}/c_stuff/Makefile \
		|| die 'sed c_stuff/Makefile failed'
}

src_compile() {
	make OPTIMIZE="${CFLAGS}" \
		PREFIX="${GAMES_PREFIX}" \
		DATADIR="${GAMES_DATADIR}" || die

	cd ${WORKDIR}/${NET_SERVER_P}
	./bootstrap.sh || die
	econf || die
}

src_install() {
	make PREFIX="${D}/${GAMES_PREFIX}" \
		DATADIR="${D}/${GAMES_DATADIR}" \
		MANDIR="${D}/usr/share/man" \
		install || die
	dosed /usr/games/bin/frozen-bubble
	dodoc AUTHORS CHANGES COPYING README

	cd ${WORKDIR}/${NET_CLIENT_P}
	make PREFIX="${D}/${GAMES_PREFIX}" \
		DATADIR="${D}/${GAMES_DATADIR}" \
		install || die

	cd ${WORKDIR}/${NET_SERVER_P}
	make DESTDIR=${D} install || die
	dodoc TODO
	newdoc README README.server

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
}