sblim-cim-client-1.3.5.ebuild

sblim-cim-client-1.3.5.ebuild (text/plain), 1.20 KB, created by jieryn on 2008-04-11 14:51:13 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

JAVA_PKG_IUSE="source test"
WANT_ANT_TASKS="ant-junit"
EANT_BUILD_TARGET="package"
EANT_DOC_TARGET="java-doc"

inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="An implementation of a WBEM services client that includes an IETF RFC 2614 compliant SLP client for CIM service discovery."
HOMEPAGE="http://sblim.wiki.sourceforge.net/CimClient"
SRC_URI="mirror://sourceforge/sblim/$P-src.zip"
LICENSE="CPL-1.0"
SLOT="1"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND=">=virtual/jre-1.4"
DEPEND="$RDEPEND
	>=virtual/jdk-1.4
	test? (
		=dev-java/junit-3*
		dev-java/ant-junit
	)
	source? ( app-arch/zip )"

S="$WORKDIR/cim-client"

src_unpack() {
	unpack $A
	cd "$S"
	epatch "$FILESDIR/$P-java-doc-without-clean.patch"
}

src_test() {
	ANT_TASKS="ant-junit" eant unittest
}

src_install() {
	java-pkg_newjar cim-client/sblimCIMClient.jar sblim-cim-client.jar
	java-pkg_newjar cim-client/sblimSLPClient.jar sblim-slp-client.jar

	dodoc cim.defaults || die "doc install failed"
	dodoc ChangeLog README NEWS || die "doc install failed"

	use doc && java-pkg_dojavadoc cim-client/doc
	use source && java-pkg_dosrc org
}