ogreode-0.7.10_p20080409.ebuild

ogreode-0.7.10_p20080409.ebuild (text/plain), 1.21 KB, created by James Le Cuirot on 2008-04-11 14:14:11 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit base cvs autotools

ECVS_SERVER="cvs.ogre3d.org:/cvsroot/ogre"
ECVS_MODULE="ogreaddons/ogreode"
ECVS_UP_OPTS="${ECVS_UP_OPTS} -D ${PV##*_p}"
ECVS_CO_OPTS="${ECVS_CO_OPTS} -D ${PV##*_p}"
PATCHES="${FILESDIR}/${P}-gcc-4.patch"

DESCRIPTION="OgreODE is an ODE physics wrapper for OGRE"
HOMEPAGE="http://www.ogre3d.org/wiki/index.php/OgreODE"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND="dev-games/ogre
	dev-games/ode
	dev-utils/tiny-xml"
DEPEND="${RDEPEND}"

S=${WORKDIR}/ogreaddons/${PN}

src_unpack() {
	cvs_src_unpack
	cd "${S}"
	
	# Use external tiny-xml instead.
	sed -i "/tinyxml/d" {loader,prefab}/src/Makefile.am
	
	# Fix \ followed by blank line. automake doesn't like these.
	sed -i -r ":x;/\\\\$/{N;s/\\\\\n(#.*)?$//;Tx}" {loader,prefab}/src/Makefile.am
	
	# Fix for latest version of tiny-xml.
	sed -i "s:ELEMENT:TINYXML_ELEMENT:g" loader/src/OgreOdeDotLoader.cpp
	
	# Don't build the examples, hence OIS isn't needed.
	sed -i "s:\bdemos\b::g" Makefile.am
	sed -i -r "/\b(ois|OIS)(\b|_)/d" configure.ac
	
	eautoreconf
}

src_compile() {
	LIBS="-ltinyxml" econf || die
	emake || die
}