smack-3.0.4.ebuild

smack-3.0.4.ebuild (text/plain), 1.27 KB, created by Kenneth Prugh (RETIRED) on 2008-04-07 21:35:04 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/smack/smack-2.2.1.ebuild,v 1.3 2007/04/28 20:53:04 nelchael Exp $

JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2 versionator

MY_P=${PN}_src_$(replace_all_version_separators '_')

DESCRIPTION="An Open Source XMPP (Jabber) client library for instant messaging and presence"
HOMEPAGE="http://www.igniterealtime.org/projects/smack/"
SRC_URI="http://www.igniterealtime.org/builds/${PN}/${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="3"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

COMMON_DEP="dev-java/xpp3
	dev-java/ant-contrib"

DEPEND=">=virtual/jdk-1.5
	${COMMON_DEP}"
	
RDEPEND=">=virtual/jre-1.5
	${COMMON_DEP}"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}

	cd "${S}"
	rm -f *.jar build/lib/*.jar build/merge/*.jar build/*.jar

	cd "${S}/build"
	java-pkg_jar-from ant-contrib

	cd "${S}/build/merge"
	java-pkg_jar-from xpp3
	sed -i -e '/zipfileset/d' "${S}/build/build.xml" || die
}

EANT_BUILD_XML="build/build.xml"
EANT_EXTRA_ARGS="-Djavadoc.dest.dir=api"

src_install() {
	java-pkg_dojar target/*.jar

	dohtml *.html

	use doc && {
		java-pkg_dohtml -r documentation/*
		java-pkg_dojavadoc api
	}
	use source && java-pkg_dosrc source/*
}