glulxe-0.4.3.ebuild

glulxe-0.4.3.ebuild (text/plain), 1006 bytes, created by David Leverton on 2008-04-03 13:56:07 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic games

MY_P=${P//./}
DESCRIPTION="An interpreter for the Glulx Virtual Machine"
HOMEPAGE="http://www.eblong.com/zarf/glulx/"
SRC_URI="mirror://ifarchive/programming/glulx/interpreters/${PN}/${MY_P}.tar.gz
	http://www.eblong.com/zarf/glulx/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="verify"

DEPEND="dev-games/glkloader"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/glulxe-0.4.3-user-CFLAGS.patch
	epatch "${FILESDIR}"/glulxe-0.4.3-gargoyle.patch
	sed -i -e "s,@PV@,${PV}," unixstrt.c || die "sed failed"
}

src_compile() {
	use verify && append-flags -DVERIFY_MEMORY_ACCESS=1
	emake \
		GLKINCLUDEDIR=/usr/include/glk \
		GLKMAKEFILE=Make.glkloader \
		|| die "emake failed"
}

src_install() {
	dogamesbin glulxe || die "dogamesbin failed"
	dodoc README || die "dodoc failed"
	prepgamesdirs
}