# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils autotools

MY_P=${P//./}
DESCRIPTION="An X Window implementation of the Glk API"
HOMEPAGE="http://www.eblong.com/zarf/glk/"
SRC_URI="mirror://ifarchive/programming/glk/implementations/${MY_P}.tar.Z
	http://www.eblong.com/zarf/glk/${MY_P}.tar.Z"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="jpeg png sdl"

RDEPEND="x11-libs/libX11
	jpeg? ( media-libs/jpeg )
	png? ( media-libs/libpng )
	sdl? ( media-libs/libsdl
		media-libs/sdl-mixer )"
DEPEND="${RDEPEND}
	dev-games/glkloader
	dev-util/pkgconfig"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# patch from http://www.ifarchive.org/if-archive/programming/glk/implementations/patches/xglk0411-sdl-mixer-sound.tgz
	# by Adam Thornton, fixes a number of issues and adds sound
	epatch "${FILESDIR}"/xglk-sdl-mixer-24bit-sanity.diff
	epatch "${FILESDIR}"/xglk-0.4.11-64bit.patch
	epatch "${FILESDIR}"/xglk-0.4.11-optional-sdl.patch
	epatch "${FILESDIR}"/xglk-0.4.11-garglk-extensions.patch

	cp "${FILESDIR}"/xglk-0.4.11-configure.ac configure.ac || die "cp configure.ac failed"
	cp "${FILESDIR}"/xglk-0.4.11-Makefile.am Makefile.am || die "cp Makefile.am failed"
	sed -i -e "s,@PV@,${PV}," configure.ac || die "sed failed"
	eautoreconf

	rm glk.h gi_blorb.h gi_dispa.h glkstart.h || die "rm glk headers failed"
}

src_compile() {
	econf $(use_with jpeg) \
		$(use_with png) \
		$(use_with sdl) || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc PREFS README TODO || die "dodoc failed"

	insinto /etc/glkloader.d
	cat >"${T}"/xglk.rc <<-EOF
		[X]
		path = /usr/$(get_libdir)/libxglk.so
	EOF
	doins "${T}"/xglk.rc || die "doins xglk.rc failed"
}