# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit webapp depend.php versionator eutils

MY_P=${PN}$(replace_all_version_separators '_')
DESCRIPTION="Bibliographic and quotations/notes management and article authoring system"
HOMEPAGE="http://wikindx.sourceforge.net"
SRC_URI="mirror://sourceforge/wikindx/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

S=${WORKDIR}/${PN}$(get_major_version)

need_httpd_cgi
need_php

pkg_setup() {
	webapp_pkg_setup
	require_php_with_use mysql xml
}

src_install() {
	webapp_src_preinst

	# install docs
	local DOCS="CHANGELOG CUSTOMIZATION DISCLAIMER INSTALL README \
		README_CMS README_RSS UPGRADE"
	dodoc "${DOCS}"
	dohtml -r docs/*
	rm -rf "${DOCS}" docs

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	# make certain directories writable (see ${HOMEPAGE}/install.html)
	local DIRS="files attachments papers styles/bibliography"
	for dir in $DIRS; do
		webapp_serverowned -R "${MY_HTDOCSDIR}/${dir}"
	done

	webapp_configfile "${MY_HTDOCSDIR}"/config.php
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install
}