# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2


inherit autotools distutils eutils flag-o-matic toolchain-funcs versionator python multilib

DESCRIPTION="SALOME : The Open Source Integration Platform for Numerical Simulation. GUI component"
HOMEPAGE="http://www.salome-platform.org"
SRC_URI="salome-3.2.6.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="doc corba pyconsole glviewer plot2dviewer supervgraphviewer occviewer vtkviewer salomeobject opengl openpbs mpi debug"
RESTRICT="fetch"

RDEPEND="opengl?  ( virtual/opengl )
	mpi?     ( sys-cluster/mpich2 )
	debug?   ( dev-util/cppunit )
	openpbs? ( sys-cluster/torque )
	corba?   ( dev-python/omniorbpy 
	 	    net-misc/omniORB )"

DEPEND="${RDEPEND}
	 >=sci-misc/salome-kernel-3.2.6"

MODULE_NAME="GUI"
MY_S="${WORKDIR}/src${PV}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"
GUI_ROOT_DIR="/opt/salome-${PV}/${MODULE_NAME}"
export OPENPBS="/usr"


pkg_nofetch()
{
	einfo "You have to download manually the source code. You can download it from :"
	einfo "   http://www.salome-platform.org/download/dl326"
	einfo ""
	einfo "Put the archive in the \"/usr/portage/distfile\" directory and rename it \"salome-3.2.6.tar.gz\""
}


src_unpack()
{
	python_version

	if ! built_with_use sci-libs/vtk python ; then
		die "You must rebuild sci-libs/vtk with python USE flag"
	fi

	unpack ${A}
	cd ${WORKDIR}/src${PV}
	epatch ${FILESDIR}/salome-gui-3.2.6.patch
	epatch ${FILESDIR}/salome-gui-3.2.6_sip-4.1.7.patch
	epatch ${FILESDIR}/salome-gui-3.2.6_qwt-4.patch

	# If vtk-5.O is used, include directory is named vtk-5.0 and not vtk
	if has_version ">=sci-libs/vtk-5.0"; then
	   einfo "vtk version 5 detected"
	   append-flags -I/usr/include/vtk-5.0
	   epatch ${FILESDIR}/salome-gui-vtk-5.0.patch
	else
	   einfo "vtk version 4 or prior detected";
	fi

	cd "${MY_S}"

	rm -r -f autom4te.cache
	./build_configure
}


src_compile()
{
	cd "${MY_S}"

	# CXXFLAGS are slightly modified to allow the compilation of
	# salome-gui with OpenCascade and gcc-4.1.x
	if version_is_at_least "4.1" $(gcc-version) ; then
		append-flags -ffriend-injection -fpermissive
	fi

	# Compiler and linker flags
	if use amd64 ; then
		append-flags -m64
	fi

	# Fix a bug
	# 
	# Fix a bug concerning a missing header	
	append-flags -I${MY_S}/../KERNEL_SRC_${PV}/src/Basics/Test

	#
	# Configuration
	#



	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
	      --libdir=${INSTALL_DIR}/$(get_libdir)/salome \
	      $(use_with mpi mpich) \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with debug cppunit /usr ) \
	      $(use_with opengl ) \
	      $(use_with openpbs ) \
	      $(use_enable salomeobject salomeObject) \
	      $(use_enable vtkviewer vtkViewer) \
	      $(use_enable occviewer occViewer) \
	      $(use_enable supervgraphviewer supervGraphViewer) \
	      $(use_enable plot2dviewer plot2dViewer) \
	      $(use_enable glviewer glViewer) \
	      $(use_enable pyconsole pyConsole) \
	      $(use_enable corba corba-gen) \
	      || die "configuration failed"

	MAKEOPTS="-j1" emake || die "Compilation failed"
}


src_install() {
	cd ${MY_S}
	emake prefix="${D}/${INSTALL_DIR}" \
	      docdir="${D}/${INSTALL_DIR}/doc/salome" \
	      infodir="${D}/${INSTALL_DIR}/share/info" \
	      datadir="${D}/${INSTALL_DIR}/share/salome" \
	      libdir="${D}/${INSTALL_DIR}/$(get_libdir)/salome" install \
	      || die "emake install failed"

	echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
	echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/lib/python${PYVER}/site-packages/salome" >> ./90${P}
	doenvd 90${P}
	rm adm_local/Makefile adm_local/unix/make_commence adm_local/unix/make_conclude adm_local/unix/make_omniorb
	insinto "${INSTALL_DIR}"
	doins -r adm_local
	if use doc; then
	   dodoc AUTHORS ChangeLog COPYING INSTALL LICENCE NEWS README README.FIRST.txt
	fi
}