slrn-9999.ebuild

slrn-9999.ebuild (text/plain), 1.26 KB, created by mren on 2008-03-17 00:25:56 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils subversion

DESCRIPTION="a s-lang based newsreader"
HOMEPAGE="http://slrn.sourceforge.net"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="nls ssl uudeview vim-syntax"

RDEPEND="virtual/mta
	app-arch/sharutils
	>=sys-libs/slang-2.1.3
	ssl? ( dev-libs/openssl )
	uudeview? ( dev-libs/uulib )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

ESVN_REPO_URI="https://slrn.svn.sourceforge.net/svnroot/slrn/trunk"
ESVN_PROJECT="slrn"

src_unpack() {
	subversion_src_unpack
	epatch "${FILESDIR}/minimal_multipart_0.9.9-87.patch"
	epatch "${FILESDIR}/us-ascii_override_0.9.9-87.patch"
}

src_compile() {
	econf --with-docdir=/usr/share/doc/${PF} \
		--with-slrnpull $(use_with uudeview) \
		$(use_enable nls) $(use_with ssl)

	emake || die "emake failed."
}

src_install () {
	# w/o these two dodir's I got errors (No such file or directory). Therefore
	# I was adviced in #gentoo-dev-help to put these into the ebuild
	dodir /usr/share/man/man1/
	dodir /usr/bin
	
	emake DESTDIR="${D}" install || die "emake install failed."
	prepalldocs

	if use vim-syntax; then
		insinto /usr/share/vim/vimfiles/syntax
		doins "${FILESDIR}/slrnrc.vim"
	fi
}