# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/acx/acx-0.3.37_p20080112.ebuild,v 1.2 2008/02/07 21:03:52 spb Exp $

inherit linux-mod

PATCHLEVEL=${PV##*_p}

DESCRIPTION="Driver for the ACX100 and ACX111 wireless chipset (CardBus, PCI, USB)"
HOMEPAGE="http://acx100.sourceforge.net/"
SRC_URI="http://downloads.sourceforge.net/acx100/${PN}-${PATCHLEVEL}.tar.bz2"

LICENSE="GPL-2 as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE="debug pci usb"

RDEPEND="net-wireless/wireless-tools
		net-wireless/acx-firmware"

S=${WORKDIR}/${PN}-${PATCHLEVEL}

MODULE_NAMES="acx(net:${S})"
CONFIG_CHECK="WIRELESS_EXT FW_LOADER"
		use pci && CONFIG_CHECK+=" PCI"
		use usb && CONFIG_CHECK+=" USB_SUPPORT"
BUILD_TARGETS="modules"

pkg_setup() {
	if (! use pci && ! use usb); then
		ewarn "Both the PCI and USB drivers are disabled due to USE flags. You need to set at least one."
		die "Neither pci nor usb USE flags enabled."
	fi
	linux-mod_pkg_setup
	BUILD_PARAMS="-C ${KV_DIR} SUBDIRS=${S}"
}

src_unpack() {
	unpack ${A}
	chmod ug+w . -R

	cd $S
	if ! use pci; then
		einfo "Disabling PCI support."
		sed -i '/^#define CONFIG_ACX_PCI 1/d' acx_config.h || die "Failed to disable PCI support"
	fi
	if ! use usb; then
		einfo "Disabling USB support."
		sed -i '/^#define CONFIG_ACX_USB 1/d' acx_config.h || die "Failed to disable USB support"
	fi
	# The default acx_config.h has some rather over-zealous debug output.
	if ! use debug; then
		sed -i '/^#define ACX_DEBUG/s/2/0/' acx_config.h || die "Failed to disable debug support"
	fi
}

src_install() {
	linux-mod_src_install

	dodoc README
}