updated mediatomb-0.11.0 ebuild

mediatomb-0.11.0.ebuild (text/plain), 3.78 KB, created by BT on 2008-03-03 11:17:32 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="MediaTomb is an open source UPnP MediaServer"
HOMEPAGE="http://www.mediatomb.cc/"
SRC_URI="mirror://sourceforge/mediatomb/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl debug exif expat ffmpeg id3 javascript libextractor mysql taglib"
RDEPEND="!mysql? ( >=dev-db/sqlite-3 )
	javascript? ( dev-lang/spidermonkey )
	expat? ( dev-libs/expat )
	id3? ( media-libs/id3lib )
	exif? ( media-libs/libexif )
	libextractor? ( media-libs/libextractor )
	taglib? ( media-libs/taglib )
	ffmpeg? ( media-video/ffmpeg )
	curl? ( net-misc/curl )
	sys-apps/file
	sys-libs/zlib
	virtual/libiconv
	mysql? ( virtual/mysql )"
DEPEND="${RDEPEND}"

MEDIATOMB_HOMEDIR="/var/lib/mediatomb"
MEDIATOMB_CONFDIR="/etc/mediatomb"
MEDIATOMB_PIDDIR="/var/run/mediatomb"

pkg_setup() {
	# disable id3lib support if id3 and taglib use are enabled
	if use id3 && use taglib; then
		ewarn "id3 and taglib USE flags are enabled. id3lib support will be disabled."
	fi

	# disable libextractor support if ffmpeg and libextractor use are enabled
	if use ffmpeg && use libextractor; then
		ewarn "ffmpeg and libextractor USE flags are enabled. libextractor support will be disabled."
	fi

	# create the mediatomb group and user
	enewgroup mediatomb
	enewuser mediatomb -1 -1 /dev/null mediatomb
}

src_compile() {
	local myconf

	# disable sqlite3 support if mysql use is enabled
	if use mysql; then
		myconf="${myconf} --enable-mysql --disable-sqlite3"
	else
		myconf="${myconf} --disable-mysql --enable-sqlite3"
	fi

	# disable id3lib support if id3 and taglib use are enabled
	if use id3 && use taglib; then
		myconf="${myconf} --enable-taglib --disable-id3lib"
	else
		myconf="${myconf} $(use_enable id3 id3lib) $(use_enable taglib)"
	fi

	# disable libextractor support if ffmpeg and libextractor use are enabled
	if use ffmpeg && use libextractor; then
		myconf="${myconf} --enable-ffmpeg --disable-libextractor"
	else
		myconf="${myconf} $(use_enable ffmpeg) $(use_enable libextractor)"
	fi

	econf \
		--prefix=/usr \
		$(use_enable curl) \
		$(use_enable debug tombdebug) \
		$(use_enable exif libexif) \
		$(use_enable expat) \
		$(use_enable javascript libjs) \
		--enable-external-transcoding \
		--enable-libmagic \
		--enable-protocolinfo-extension \
		${myconf} \
		|| die "Configure failed!"

	emake || die "Make failed!"
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed!"

	dodoc AUTHORS ChangeLog NEWS README

	# install the mediatomb init.d and conf.d files
	newinitd "${FILESDIR}/${PN}.initd" mediatomb
	newconfd "${FILESDIR}/${PN}.confd" mediatomb

	# create the mediatomb pid directory
	dodir "${MEDIATOMB_PIDDIR}"
	keepdir "${MEDIATOMB_PIDDIR}"
	fowners mediatomb:mediatomb "${MEDIATOMB_PIDDIR}"

	# install the mediatomb config file
	insinto "${MEDIATOMB_CONFDIR}"
	newins "${FILESDIR}/${P}.config" config.xml
	fperms 0600 "${MEDIATOMB_CONFDIR}/config.xml"
	fowners mediatomb:mediatomb "${MEDIATOMB_CONFDIR}/config.xml"

	# create the mediatomb home directory
	dodir "${MEDIATOMB_HOMEDIR}"
	fowners mediatomb:mediatomb "${MEDIATOMB_HOMEDIR}"

	# prevent the mediatomb home directory from being removed
	keepdir "${MEDIATOMB_HOMEDIR}"
}

pkg_postinst() {
	if use mysql; then
		elog "MediaTomb has been built with MySQL support. You will"
		elog "find information on how to setup MediaTomb with MySQL"
		elog "in section 4.2.2. and 6.1. of the MediaTomb documentation,"
		elog "which is available at:"
		elog "http://mediatomb.cc/pages/documentation"
		elog
	fi

	elog "The MediaTomb Web UI can be reached at:"
	elog "http://localhost:49152/"
	elog
	elog "To start MediaTomb:"
	elog "/etc/init.d/mediatomb start"
	elog
	elog "To start MediaTomb at boot:"
	elog "rc-update add mediatomb default"
}