grcompiler-2.4.ebuild

grcompiler-2.4.ebuild (text/plain), 1.26 KB, created by David Leverton on 2008-02-12 03:56:45 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1

inherit eutils autotools

ESVN_BOOTSTRAP="eautoreconf"

DESCRIPTION="Graphite compiler"
HOMEPAGE="http://scripts.sil.org/RenderingGraphite"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="|| ( LGPL-2.1 CPL-0.5 )"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug doc"

RDEPEND="=dev-libs/icu-3.8*"
# silgraphite is only needed for the tests, however configure checks
# for it unconditionally
DEPEND="${RDEPEND}
	app-text/docbook-xml-dtd:4.5
	app-text/xmlto
	dev-util/pkgconfig
	media-libs/silgraphite"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/grcompiler-r815-debug-CFLAGS.patch
	epatch "${FILESDIR}"/grcompiler-r815-dynamic-icu-3.8.patch
	epatch "${FILESDIR}"/grcompiler-r767-include-path.patch
	epatch "${FILESDIR}"/grcompiler-r815-tests.patch
	epatch "${FILESDIR}"/grcompiler-r815-xmlto.patch
	eautoreconf
}

src_compile() {
	econf $(use_enable debug) || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README NEWS ChangeLog TODO || die "dodoc failed"

	if use doc; then
		dodoc doc/*.{pdf,rtf} || die "dodoc failed"
	fi
	rm -rf "${D}"/usr/share/doc/grcompiler
}