# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils multilib qt4

DESCRIPTION="Qt Cryptographic Architecture (QCA)"
HOMEPAGE="http://delta.affinix.com/qca/"
SRC_URI="http://delta.affinix.com/download/qca/${PV%.*}/${P}.tar.bz2"

LICENSE="LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples"
RESTRICT="test"

DEPEND="$(qt4_min_version 4.2.0)
	!<app-crypt/qca-1.0-r3"
RDEPEND="${DEPEND}"

QT4_OPTIONAL_BUILT_WITH_USE_CHECK="debug"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-debug-same-pkgconfig-file.patch
}

src_compile() {
	local myconf=
	use debug && myconf="--debug" || myconf="--release"

	# Multilib fix
	local _libdir=$(get_libdir)
	sed -i -e "/pcfiles\.path/s:lib:${_libdir}:" "${S}"/configure \
		|| die "Multilib fix failed."

	./configure \
		--prefix=/usr \
		--qtdir=/usr \
		--includedir="/usr/include/qca2" \
		--libdir="/usr/${_libdir}/qca2" \
		--no-separate-debug-info \
		--disable-tests \
		${myconf} \
		|| die "configure failed"

	eqmake4 ${PN}.pro
	emake || die "emake failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
	dodoc README TODO

	cat <<-EOF > "${T}"/44qca2
	LDPATH=/usr/$(get_libdir)/qca2
	EOF
	doenvd "${T}"/44qca2

	if use doc; then
		dohtml "${S}"/apidocs/html/* || die "Failed to install documentation"
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/
		doins -r "${S}"/examples || die "Failed to install examples"
	fi
}