# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit eutils cvs

DESCRIPTION="Live CVS ebuild of Canon DigiCam Capture Utility"
HOMEPAGE="http://capture.sourceforge.net/"
SRC_URI=""
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="+debug extras gtk v4l jpeg"

RDEPEND=">=media-libs/libptp2-1.0.1
		extras? ( >=dev-perl/Time-modules-2006.0814 )
		v4l? ( >=media-video/vloopback-1.1_rc1
			jpeg? ( >=media-libs/jpeg-6b-r7 )
		)"
DEPEND="$RDEPEND
		>=dev-util/pkgconfig-0.20"

ECVS_SERVER="capture.cvs.sourceforge.net:/cvsroot/capture"
ECVS_USER="anonymous"
ECVS_PASS=""
ECVS_AUTH="pserver"
ECVS_MODULE="capture"
ECVS_BRANCH=""

S=${WORKDIR}/${ECVS_MODULE}

pkg_setup() {
	if use jpeg && ! use v4l ; then
		einfo "jpeg useflag enables viewfinder jpeg images decoding through"
		einfo "libjpeg, it gives a YUV420P stream when feeding vloopback's"
		einfo "v4l input device instead of a RGB24 stream as provided by the"
		einfo "finepix-jpeg decoding routine provided internally"
		die "enabling jpeg useflag not possible without enabled v4l useflag"
	fi
}

src_unpack() {
	cvs_src_unpack
	cd ${S}

	use v4l && epatch "${FILESDIR}/canon-capture-cvs-v4l_jpeg.diff.bz2"
	sed -i -e 's:$(PREFIX):$(DESTDIR)/usr:g' \
		-e 's/\(^EXECUTABLE.*:=\).*/\1 canon-capture/' \
		-e 's/^CFLAGS\s*=\s*/CFLAGS += /' \
		-e '/^HAVE_GTK/ d' \
		Makefile
}

src_compile() {
	local makeargs

	use debug || makeargs="${makeargs} DISTBUILD=TRUE"
	use gtk && makeargs="${makeargs} HAVE_GTK=-DHAVE_GTK"
	use v4l && makeargs="${makeargs} HAVE_V4L=-DHAVE_V4L"
	use v4l && use jpeg && makeargs="${makeargs} HAVE_JPEG=-DHAVE_JPEG"
	emake $makeargs || die "Build failed"
}

src_install() {
	make DESTDIR=${D} install || die "Installation failed"

	sed -i -e 's:./capture:canon-capture:' example.sh
	dodoc AUTHORS COPYING ChangeLog README example.sh

	if use extras ; then
		sed -i -e 's:./capture:canon-capture:' job
		into /usr
		newbin job canon-capture-job
	fi
}

pkg_postinst() {
	einfo "canon-capture + optional v4l feeding has it's roots here:"
	einfo "Canon PTP Modification Analysis: http://www.jalkapallo.org/superkolik/canon.html"
	einfo "V4L patch: http://www.studenti.unina.it/~ospite/section/it/dev/canoncam.html#English"
}