# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License, v2 or later
# $Header: $

S="${WORKDIR}/glade-${PV}-src"
DESCRIPTION="The GNAT implementation of the ARM Annex for Distributed Systems."
SRC_URI="http://gd.tuwien.ac.at/languages/ada/gnat/3.15p/glade/glade-${PV}-src.tgz"

HOMEPAGE="http://www.gnat.com/"
LICENSE="GMGPL"
DEPEND="dev-lang/gnat"
RDEPEND=""
SLOT="0"
IUSE=""
KEYWORDS="~x86"

inherit ada

src_compile() {
	local CFLAGS="${ADACFLAGS} -fPIC"
	local ADACFLAGS="${ADACFLAGS} -fPIC"

	./configure \
		--host=${CHOST} \
		--prefix=/usr \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man || die "./configure failed"

	emake || die

	${ADAC} -shared -Wl,-soname,libgarlic-${PV}.so.1 \
		-o Garlic/libgarlic-${PV}.so.1 Garlic/*.o -lc
}

src_install () {
	make prefix=${D}/usr \
		GARLIC=${D}/usr/lib/ada/adainclude/garlic install || die

	dodoc COPYING INSTALL NEWS README

	insinto /usr/lib/ada/adalib/garlic
	chmod 0755 Garlic/libgarlic-${PV}.so.1
	doins Garlic/libgarlic-${PV}.so.1
	dosym /usr/lib/ada/adalib/garlic/libgarlic-${PV}.so.1 \
		/usr/lib/ada/adalib/garlic/libgarlic-${PV}.so
}