# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="A Glk library which dynamically loads another Glk library"
HOMEPAGE="http://www.eblong.com/zarf/glk"
SRC_URI="http://mirror.ifarchive.org/if-archive/programming/glk/implementations/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
IUSE=""
KEYWORDS="~amd64 ~x86"

DEPEND=""
PDEPEND="virtual/glk"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/glkloader-0.3.2-gentoo.patch
	epatch "${FILESDIR}"/glkloader-0.3.2-Makefile.patch
}

src_compile() {
	cd xpconfig || die
	econf --with-method=rcfile || die
	emake || die

	cd .. || die
	emake MULTILIB_LIBDIR="$(get_libdir)" || die
}

src_install() {
	cd xpconfig || die
	emake DESTDIR="${D}" install || die

	cd .. || die
	emake DESTDIR="${D}" MULTILIB_LIBDIR="$(get_libdir)" install || die
	dodoc ChangeLog README || die
	docinto makefile-samples || die
	dodoc makefile-samples/* || die

	keepdir /etc/glkloader.d || die
	insinto /etc || die
	newins "${FILESDIR}"/0.3.2-glkloaderrc glkloaderrc || die

	insinto /usr/include/glk || die
	doins glk.h gi_blorb.h gi_dispa.h || die
}