emelfm2-0.3.6.ebuild

emelfm2-0.3.6.ebuild (text/plain), 1.60 KB, created by Samuli Suominen (RETIRED) on 2007-12-01 09:11:37 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/emelfm2-0.3.5.ebuild,v 1.2 2007/09/07 19:12:16 josejx Exp $

inherit eutils multilib toolchain-funcs

DESCRIPTION="A file manager that implements the popular two-pane design"
HOMEPAGE="http://emelfm2.net"
SRC_URI="http://${PN}.net/rel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="acl fam gimp tracker unicode"
# IUSE="test"

DEPEND=">=x11-libs/gtk+-2.6
	fam? ( virtual/fam )
	acl? ( sys-apps/acl )
	gimp? ( >=media-gfx/gimp-2.2 )
	tracker? ( app-misc/tracker )"
RDEPEND="${DEPEND}
	dev-util/pkgconfig"
# test? ( dev-util/splint )

RESTRICT="test"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e "s:emelfm2/emelfm2_48.png:emelfm2:" docs/desktop_environment/emelfm2.desktop
	sed -i -e "s:FIX)/lib:FIX)/$(get_libdir):" Makefile
}

src_compile() {
	local myconf

	use gimp && myconfg="${myconf} WITH_THUMBS=1"
	use tracker && myconf="${myconf} WITH_TRACKER=1"
	use acl && myconf="${myconf} WITH_ACL=1"
	use unicode && myconf="${myconf} FILES_UTF8ONLY=1"

	if use fam; then
		if has_version "app-admin/gamin"; then
			myconf="${myconf} USE_GAMIN=1"
		else
			myconf="${myconf} USE_FAM=1"
		fi
	else
		myconf="${myconf} USE_FAM=0"
	fi

	emake ICONDIR="/usr/share/pixmaps" PREFIX="/usr" CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" ${myconf} || die "emake failed."
}

src_install() {
	emake ICONDIR="${D}"/usr/share/pixmaps \
		PREFIX="${D}"/usr install || die "emake install failed."
	newicon icons/emelfm2_48.png emelfm2.png
	prepalldocs
}