# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
DESCRIPTION="a CD drive emulator for Linux -- userspace daemon"
HOMEPAGE="http://cdemu.sourceforge.net/"
OUTER_TARBALL="userspace-cdemu-${PV//./-}.tar"
INNER_TARBALL="${PN}-1.0.0.tar.gz"
SRC_URI="http://kabelkaos.net/cdemu/cdemu-vhba/${OUTER_TARBALL}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
S="${WORKDIR}/${PN}-1.0.0"
IUSE="alsa"
RDEPEND=">=dev-libs/glib-2.6
	>=sys-apps/dbus-0.60
	>=dev-libs/dbus-glib-0.61
	>=dev-libs/libdaemon-0.10
	alsa? ( >=media-libs/alsa-lib-1.0.0 )
	>=app-cdr/libmirage-${PV}
	>=app-cdr/vhba-module-${PV}"
DEPEND="${RDEPEND}
	dev-util/unifdef"

src_unpack() {
	cd "${WORKDIR}"
	unpack ${A}
	unpack "./${INNER_TARBALL}"
}

src_compile() {
	econf --with-distro=none $(use_enable alsa) || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README
	unifdef "${FILESDIR}/${PN}.conf.d" \
		-$(use alsa && echo D || echo U)ALSA \
		>"${T}/${PN}"
	doconfd "${T}/${PN}"
	unifdef "${FILESDIR}/${PN}.init.d" \
		-$(use alsa && echo D || echo U)ALSA \
		>"${T}/${PN}"
	doinitd "${T}/${PN}"
}