# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils

DESCRIPTION="2D multiple-robot simulator."
HOMEPAGE="http://playerstage.sourceforge.net/index.php?src=stage"
SRC_URI="mirror://sourceforge/playerstage/stage-${PV}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"

IUSE="doc"

RDEPEND="
	>=x11-libs/gtk+-2.4
	>=sci-electronics/player-2.0.2
	x11-apps/rgb"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"


src_unpack() {
	unpack ${A}
	cd "${S}"	
	
	if use doc; then
		epatch "${FILESDIR}/stage-2.0.3-docdst-fix.diff" || die "epatch failed"
	fi

	sed -i -e \
		"s;/usr/X11R6/lib/X11/rgb.txt;/usr/share/X11/rgb.txt;" \
		configure.ac || die "sed failed"
	
	eautoreconf
}

src_compile() {
	#Disable gnome-canvas since its experimental
	econf --disable-gnomecanvas || die "econf failed"
	emake || die "emake failed"
	
	if use doc; then
		pushd docsrc
		doxygen -u stage.dox || die "doxygen failed"
		touch header.html
		emake "doc" || die "emake doc failed"
		popd
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if use doc; then
		pushd docsrc
		emake DESTDIR="${D}" "doc-install" || die "emake doc-install failed"
		popd
	fi

	dodoc AUTHORS ChangeLog NEWS README
}