# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/stunnel-4.20.ebuild,v 1.11 2007/10/08 07:53:41 corsair Exp $

inherit autotools ssl-cert eutils

DESCRIPTION="TLS/SSL - Port Wrapper"
HOMEPAGE="http://stunnel.mirt.net/"
SRC_URI="http://www.stunnel.org/download/stunnel/src/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="ipv6 selinux tcpd"

DEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=dev-libs/openssl-0.9.6j"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-stunnel )"

pkg_setup() {
	enewgroup stunnel
	enewuser stunnel -1 -1 -1 stunnel
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-libwrap.patch
	eautoreconf

	# Hack away generation of certificate
	sed -i -e "s/^install-data-local:/do-not-run-this:/" \
		tools/Makefile.in || die "sed failed"
}

src_compile() {
	econf $(use_enable ipv6) \
		$(use_enable tcpd libwrap) || die "econf died"
	emake || die "emake died"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	rm -rf "${D}"/usr/share/doc/${PN}
	rm -f "${D}"/{etc/stunnel/stunnel.conf-sample,usr/sbin/stunnel3} \
		"${D}"/usr/share/man/man8/{stunnel.fr.8,stunnel.pl.8}

	dodoc AUTHORS BUGS CREDITS PORTS README TODO ChangeLog doc/en/transproxy.txt
	dohtml doc/stunnel.html doc/en/VNC_StunnelHOWTO.html tools/ca.html \
		tools/importCA.html

	insinto /etc/stunnel
	newins "${FILESDIR}"/stunnel.conf stunnel.conf
	newinitd "${FILESDIR}"/stunnel.rc6 stunnel
	# Check if there's currently an cert already there
	if [ ! -f /etc/stunnel/stunnel.key ]; then
		docert stunnel
		fowners stunnel:stunnel /etc/stunnel/stunnel.{conf,crt,csr,key,pem}
		fperms 0640 /etc/stunnel/stunnel.{conf,crt,csr,key,pem}
	fi

	keepdir /var/run/stunnel
	fowners stunnel:stunnel /var/run/stunnel

}

pkg_postinst() {
	if [ ! -z "$(grep /etc/stunnel/stunnel.pid \
		"${ROOT}"/etc/stunnel/stunnel.conf )" ] ; then

		ewarn "As of stunnel-4.09, the pid file will be located in /var/run/stunnel."
		ewarn "Please stop stunnel, etc-update, and start stunnel back up to ensure"
		ewarn "the update takes place"
		ewarn
		ewarn "The new location will be /var/run/stunnel/stunnel.pid"
	fi
}