new ebuild for DRAWxtl43

drawxtl-43.ebuild (text/plain), 1.07 KB, created by Hannes Krüger on 2007-10-31 00:21:00 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PN="DRAWxtl"
MY_P=${MY_PN}${PV}
DESCRIPTION="This software can be used to produce crystal structure drawings from structural data"
HOMEPAGE="http://www.lwfinger.net/drawxtl/"
SRC_URI="http://home.att.net/~larry.finger/drawxtl/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="examples fltk"

DEPEND="virtual/opengl
	virtual/glut
	virtual/glu
	fltk? ( >=x11-libs/fltk-1.1.6 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_PN}"

src_unpack() {
	unpack ${A}
	epatch "${FILESDIR}/${MY_P}-makefiles.patch" || die "patching failed."
}

src_compile() {
	cd source/${MY_P}
	emake || die "Build of ${MY_PN} failed."

	if use fltk; then
		cd "${S}"/source/DRAWshell${PV}
		emake || die "Build of DRAWshell failed."
	fi
}

src_install() {
	dobin exe/${MY_P}

	if use fltk; then
		dobin exe/DRAWshell${PV}
	fi

	dodoc docs/readme.txt
	insinto /usr/share/doc/${P}
	doins docs/*.pdf

	if use examples; then
		docinto examples
		dodoc examples/*
	fi
}