# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/dk-milter/dk-milter-0.4.1.ebuild,v 1.6 2006/07/18 00:55:38 langthang Exp $

inherit eutils

DESCRIPTION="A milter-based application provide DomainKeys service"
HOMEPAGE="http://sourceforge.net/projects/dk-milter/"
SRC_URI="mirror://sourceforge/dk-milter/${P}.tar.gz"

LICENSE="Sendmail-Open-Source"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ipv6"

RDEPEND="dev-libs/openssl
	>=sys-libs/db-3.2
	|| ( mail-filter/libmilter mail-mta/sendmail )"
DEPEND="${RDEPEND}"

pkg_setup() {
	enewgroup milter
	enewuser milter -1 -1 -1 milter
}

src_unpack() {
	unpack "${A}"

	cd "${S}" || die "source dir not found"

	# Postfix queue ID patch. See MILTER_README.html#workarounds
	epatch "${FILESDIR}/${P}-postfix-queueID.patch"

	local ENVDEF="-DNETUNIX -DNETINET"
	use ipv6 && ENVDEF="${ENVDEF} -DNETINET6"

	sed -e "s:@@CFLAGS@@:${CFLAGS}:" -e "s/@@ENVDEF@@/${ENVDEF}/" \
		"${FILESDIR}/gentoo.config.m4" > devtools/Site/site.config.m4 \
		|| die "failed to generate site.config.m4"
}

src_compile() {
	emake -j1 CC="$(tc-getCC)" || die "emake failed"
}

src_test() {
	emake -j1 CC="$(tc-getCC)" OPTIONS=check \
		|| die "emake check failed"
}

src_install() {
	# prepare directory for private keys.
	dodir /etc/mail/dk-filter
	fowners milter:milter /etc/mail/dk-filter
	fperms 700 /etc/mail/dk-filter

	newinitd "${FILESDIR}/dk-filter.init" dk-filter \
		|| die "newinitd failed"
	newconfd "${FILESDIR}/dk-filter.conf" dk-filter \
		|| die "newconfd failed"

	dodir /usr/bin /usr/share/man/man8
	emake -j1 DESTDIR=${D} MANROOT=/usr/share/man/man \
		install || die "make install failed"

	dobin "$FILESDIR"/gentxt.sh || die "dobin failed"
}

pkg_postinst() {
	pkg_setup # create milter user
}