vdr-vdrrip-0.3.0-r8.ebuild

vdr-vdrrip-0.3.0-r8.ebuild (text/plain), 1.49 KB, created by cmuelle8 on 2007-09-27 01:44:16 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit vdr-plugin eutils

DESCRIPTION="VDR plugin: convert video-recordings to mpeg4 for burning on CDs"
HOMEPAGE="http://www.a-land.de/"
SRC_URI="http://www.a-land.de/${P}.tgz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=media-video/vdr-1.3.7"
RDEPEND="${DEPEND}
		>=media-video/mplayer-1.0_pre8
		sys-process/procps
		sys-apps/util-linux"
# media-video/vdrsync seems to be optional

src_unpack() {
	vdr-plugin_src_unpack

	epatch ${FILESDIR}/vdrrip-0.3.0-20070925-vdr1.3.7-mplayer-merged.diff
}

src_install() {
	vdr-plugin_src_install

	# save config files
	insinto /etc/vdr/plugins/vdrrip
	newins scripts/queuehandler.sh.conf vdrrip-qh.conf
	newconfd ${FILESDIR}/vdrrip-qh.conf vdrrip-qh
	# add start script
	doinitd ${FILESDIR}/vdrrip-qh
	# save in bin
	newbin scripts/queuehandler.sh vdrrip-qh
}

pkg_postinst() {
	vdr-plugin_pkg_postinst

	elog "You should have a look at this files:"
	elog
	elog "* /etc/vdr/plugins/vdrrip/vdrrip-qh.conf"
	elog
	elog "Use vdrrip-qh to start the vdrrip queue handler."
	elog "You can also run 'rc-update add /etc/init.d/vdrrip-qh default' to"
	elog "let vdrrip-qh start automaticly when the system starts."

	elog
	elog "If you used vdrrip before, mind that it runs by default as user vdr now."
	elog "To correct the permissions you should execute this:"
	elog "# chown vdr:vdr -R /var/log/vdrrip-qh /tmp/vdrrip /tmp/queuehandler.vdr"
	elog
}