# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="OpenEXR Viewers"
SRC_URI="download.savannah.nongnu.org/releases/openexr/${P}.tar.gz"
HOMEPAGE="http://openexr.com/"

SLOT="0"
LICENSE="ILM"
KEYWORDS="~x86"
IUSE_VIDEO_CARDS="video_cards_nvidia"
IUSE="doc opengl ${IUSE_VIDEO_CARDS}"

RDEPEND="media-libs/ilmbase
	media-libs/openexr
	media-libs/ctl
	media-libs/openexr_ctl
	opengl? ( virtual/opengl
		>=x11-libs/fltk-1.1.0
		video_cards_nvidia? ( media-gfx/nvidia-cg-toolkit ) )"
DEPEND="${RDEPEND}
	!<media-libs/openexr-1.5.0
	dev-util/pkgconfig"

pkg_setup() {
	if use opengl && ! built_with_use x11-libs/fltk opengl ; then
		die "You need OpenGL support in FLTK"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${P}-nvidia-automagic.patch"
	libtoolize --copy --force
	./bootstrap
}

src_compile() {
	econf \
		$(use_with opengl fltk-config /usr/bin/fltk-config) \
		$(use_enable video_cards_nvidia nvidia)
	emake || die "emake failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc AUTHORS ChangeLog LICENSE NEWS README
	use doc && cp -v doc/*.pdf "${D}usr/share/doc/${PF}"
	rm -frv "${D}usr/share/doc/OpenEXR_Viewers"*
}