net-wireless/ralink-rt73 ebuild v.1.0.4.0

ralink-rt73-1.0.4.0.ebuild (text/plain), 1.29 KB, created by Kostornoy Vladimir on 2007-09-12 01:00:21 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/ralink-rt61/ralink-rt61-1.1.1.0.ebuild,v 1.1 2007/08/29 19:32:07 genstef Exp $

inherit eutils linux-mod

DESCRIPTION="Driver for the RaLink RT73 wireless chipset"
HOMEPAGE="http://www.ralinktech.com/"
LICENSE="GPL-2"

MY_P=${P/${PN}-/RT73_Linux_STA_Drv}

SRC_URI="http://www.ralinktech.com.tw/data/${MY_P}.tar.gz"

KEYWORDS="-* amd64 x86"
IUSE=""
SLOT="0"

DEPEND=""
RDEPEND="net-wireless/wireless-tools
	!net-wireless/rt73"

S="${WORKDIR}/${MY_P}"

MODULE_NAMES="rt73(net:${S}/Module)"
BUILD_TARGETS=" "
MODULESD_RT61_ALIASES=('rausb? rt73')

CONFIG_CHECK="WIRELESS_EXT"
ERROR_WIRELESS_EXT="${P} requires support for Wireless LAN drivers (non-hamradio) & Wireless Extensions (CONFIG_WIRELESS_EXT)."

src_compile() {
	if kernel_is 2 6; then
		cp Module/Makefile.6 Module/Makefile
	elif kernel_is 2 4; then
		cp Module/Makefile.4 Module/Makefile
	else
		die "Your kernel version is not supported!"
	fi

	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install

	dodoc Module/{ReleaseNote,STA_iwpriv_ATE_usage.txt,README,iwpriv_usage.txt}

	insinto /etc/Wireless/RT73STA
	insopts -m 0600
	doins Module/rt73sta.dat
	insopts -m 0644
	doins Module/rt73.bin
}