diff -urNp suspend.org/AUTHORS suspend.x/AUTHORS
--- suspend.org/AUTHORS	1970-01-01 02:00:00.000000000 +0200
+++ suspend.x/AUTHORS	2007-09-04 08:11:55.000000000 +0300
@@ -0,0 +1,5 @@
+Rafael J. Wysocki <rjw@sisk.pl>
+Pavel Machek <pavel@suse.cz>
+Stefan Seyfried <seife@suse.de>
+Tim Dijkstra <newsuser@famdijkstra.org>
+Luca Tettamanti <kronos.it@gmail.com>
diff -urNp suspend.org/bootsplash.c suspend.x/bootsplash.c
--- suspend.org/bootsplash.c	2006-09-18 15:00:09.000000000 +0300
+++ suspend.x/bootsplash.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,7 @@
  *
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <fcntl.h>
 #include <unistd.h>
diff -urNp suspend.org/config_parser.c suspend.x/config_parser.c
--- suspend.org/config_parser.c	2007-08-31 00:23:58.000000000 +0300
+++ suspend.x/config_parser.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,7 @@
  *
  */
 
+#include "config.h"
 #include <sys/types.h>
 #include <sys/stat.h>
 #include <fcntl.h>
diff -urNp suspend.org/configure.ac suspend.x/configure.ac
--- suspend.org/configure.ac	1970-01-01 02:00:00.000000000 +0200
+++ suspend.x/configure.ac	2007-09-04 08:12:24.000000000 +0300
@@ -0,0 +1,234 @@
+#
+# configure.ac
+#
+# Copyright (C) 2007 Alon Bar-Lev <alon.barlev@gmail.com>
+#
+# This file is released under the GPLv2.
+#
+
+AC_PREREQ([2.60])
+AC_INIT([suspend], [0.6_beta1])
+AM_INIT_AUTOMAKE([${PACKAGE_NAME}], [${PACKAGE_VERSION}])
+AM_CONFIG_HEADER([config.h])
+AC_CONFIG_SRCDIR([suspend.c])
+
+AC_CANONICAL_HOST
+
+AC_ARG_ENABLE(
+	[debug],
+	[AC_HELP_STRING([--enable-debug], [Enable debug mode])],
+	,
+	[enable_debug="no"]
+)
+AC_ARG_ENABLE(
+	[minimal],
+	[AC_HELP_STRING([--enable-minimal], [Enable minimal build])],
+	,
+	[enable_minimal="no"]
+)
+AC_ARG_ENABLE(
+	[compress],
+	[AC_HELP_STRING([--enable-compress], [Enable compress support])],
+	,
+	[enable_compress="no"]
+)
+AC_ARG_ENABLE(
+	[encrypt],
+	[AC_HELP_STRING([--enable-encrypt], [Enable encryption support])],
+	,
+	[enable_encrypt="no"]
+)
+AC_ARG_ENABLE(
+	[create-device],
+	[AC_HELP_STRING([--enable-create-device], [Enable create required devices, use only if you don't have udev])],
+	,
+	[enable_create_device="no"]
+)
+AC_ARG_ENABLE(
+	[resume-static],
+	[AC_HELP_STRING([--disable-resume-static], [Build resume as dynamic module])],
+	,
+	[enable_resume_static="yes"]
+)
+AC_ARG_ENABLE(
+	[splashy],
+	[AC_HELP_STRING([--enable-splashy], [Enable splashy support])],
+	,
+	[enable_splashy="no"]
+)
+AC_ARG_WITH(
+	[devdir],
+	[AC_HELP_STRING([--with-devdir=DIR], [Use if --enable-create-device, put devices in this directory, default /dev])],
+	[devdir="${withval}"],
+	[devdir="/dev"]
+)
+AC_ARG_WITH(
+	[initramfsdir],
+	[AC_HELP_STRING([--with-initramfsdir=DIR], [Put initramfs binaries in this directory, default LIBDIR/suspend])],
+	[initramfsdir="${withval}"],
+	[initramfsdir="\$(libdir)/suspend"]
+)
+AC_ARG_WITH(
+	[libgcrypt-prefix],
+	[AC_HELP_STRING([--with-libgcrypt-prefix=DIR], [Define libgcrypt prefix, default /usr])],
+	,
+	[with_libgcrypt_prefix="/usr" ]
+)
+AC_ARG_WITH(
+	[directfb-prefix],
+	[AC_HELP_STRING([--with-directfb-prefix=DIR], [Define directfb prefix, default /usr])],
+	,
+	[with_directfb_prefix="/usr" ]
+)
+AC_ARG_WITH(
+	[resume-device],
+	[AC_HELP_STRING([--with-resume-device=DEVICE], [Define resume device (REQUIRED ONLY FOR BUILDING INITRAMFS DURING MAKE)])],
+	[RESUME_DEVICE="${withval}"]
+)
+AC_ARG_WITH(
+	[boot-dir],
+	[AC_HELP_STRING([--with-bootdir=DIR], [Define boot directory, default /boot (REQUIRED ONLY FOR BUILDING INITRAMFS DURING MAKE)])],
+	[bootdir="${withval}"],
+	[bootdir="/boot" ]
+)
+
+
+AC_PROG_CC
+AC_PROG_INSTALL
+AC_PROG_LIBTOOL		# We are using libtool so it auto-find static dependencies
+PKG_PROG_PKG_CONFIG
+AC_CHECK_PROGS([M4], [m4])
+if test "${enable_create_device}" = "yes"; then
+	AC_CHECK_PROGS([MKNOD], [mknod])
+	test -z "${MKNOD}" && AC_MSG_ERROR([mknod required for creating devices])
+fi
+
+case "${host}" in
+	i?86-*)		ARCH="x86";;
+	x86_*-*)	ARCH="x86";;
+	ppc-*)		ARCH="ppc";;
+esac
+
+if test "${ARCH}" = "x86"; then
+	AC_DEFINE([CONFIG_ARCH_X86], [1], [Define if x86 arch])
+
+	PKG_CHECK_MODULES(
+		[LIBPCI],
+		[libpci >= 2.2.4],
+		,
+		[
+			if test -z "${LIBPCI_LIBS}"; then
+				AC_CHECK_LIB(
+					[pci],
+					[pci_init],
+					[LIBPCI_LIBS="-lpci"],
+					[
+					#force rescan
+					unset ac_cv_lib_pci_pci_init
+					AC_CHECK_LIB(
+						[pci],
+						[pci_init],
+						[LIBPCI_LIBS="-lpci -lz"],
+						[AC_MSG_ERROR([Required pciutils >= 2.2.4 not found])],
+						[-lz]
+					)]
+				)
+			fi
+		]
+	)
+
+	if test -z "${LIBX86_LIBS}"; then
+		AC_ARG_VAR([LIBX86_CFLAGS], [C compiler flags for libx86])
+		AC_ARG_VAR([LIBX86_LIBS], [linker flags for libx86])
+		AC_CHECK_LIB(
+			[x86],
+			[LRMI_common_init],
+			[LIBX86_LIBS="-lx86"],
+			[AC_MSG_ERROR([Required libx86 was not found])]
+		)
+	fi
+elif test "${ARCH}" = "ppc"; then
+	AC_DEFINE([CONFIG_ARCH_PPC], [1], [Define if ppc arch])
+fi
+
+if test "${enable_compress}" = "yes"; then
+	AC_DEFINE([CONFIG_COMPRESS], [1], [Define if x86 arch])
+	if test -z "${LZO_LIBS}"; then
+		AC_ARG_VAR([LZO_CFLAGS], [C compiler flags for lzo])
+		AC_ARG_VAR([LZO_LIBS], [linker flags for lzo])
+		AC_CHECK_LIB(
+			[lzo2],
+			[lzo1x_1_compress],
+			[LZO_LIBS="-llzo2"],
+			[AC_CHECK_LIB(
+				[lzo],
+				[lzo1x_1_compress],
+				[LZO_LIBS="-llzo"],
+				[AC_MSG_ERROR([Required lzo library not found])]
+			)]
+		)
+	fi
+fi
+
+if test "${enable_encrypt}" = "yes"; then
+	AC_DEFINE([CONFIG_ENCRYPT], [1], [Define if encryption enabled])
+
+	AC_MSG_CHECKING([for libgcrypt])
+	if ! test -x "${with_libgcrypt_prefix}/bin/libgcrypt-config"; then
+		AC_MSG_ERROR([Cannot locate libgcrypt])
+	else
+		AC_MSG_RESULT([found])
+		LIBGCRYPT_CFLAGS=`"${with_libgcrypt_prefix}/bin/libgcrypt-config" --cflags`
+		LIBGCRYPT_LIBS=`"${with_libgcrypt_prefix}/bin/libgcrypt-config" --libs`
+	fi
+fi
+
+if test "${enable_splashy}" = "yes"; then
+	AC_DEFINE([CONFIG_SPLASHY], [1], [Define if splashy enabled])
+
+	if test -z "${SPLASHY_LIBS}"; then
+		AC_ARG_VAR([SPLASHY_CFLAGS], [C compiler flags for libsplashy])
+		AC_ARG_VAR([SPLASHY_LIBS], [linker flags for libsplashy])
+		AC_CHECK_LIB(
+			[splashy],
+			[splashy_open],
+			[SPLASHY_LIBS="-lsplashy"],
+			[AC_MSG_ERROR([Required libsplashy was not found])]
+		)
+	fi
+fi
+
+AC_HEADER_STDC
+AC_CHECK_HEADERS([ \
+	inttypes.h \
+	stdint.h \
+])
+
+AC_SUBST([devdir])
+AC_SUBST([initramfsdir])
+AC_SUBST([bootdir])
+AC_SUBST([LIBX86_CFLAGS])
+AC_SUBST([LIBX86_LIBS])
+AC_SUBST([LZO_CFLAGS])
+AC_SUBST([LZO_LIBS])
+AC_SUBST([LIBGCRYPT_CFLAGS])
+AC_SUBST([LIBGCRYPT_LIBS])
+AC_SUBST([SPLASHY_CFLAGS])
+AC_SUBST([SPLASHY_LIBS])
+AC_SUBST([RESUME_DEVICE])
+AM_CONDITIONAL([ENABLE_DEBUG], [test "${enable_debug}" = "yes"])
+AM_CONDITIONAL([ENABLE_MINIMAL], [test "${enable_minimal}" = "yes"])
+AM_CONDITIONAL([ARCH_X86], [test "${ARCH}" = "x86"])
+AM_CONDITIONAL([ARCH_PPC], [test "${ARCH}" = "ppc"])
+AM_CONDITIONAL([ENABLE_ENCRYPT], [test "${enable_encrypt}" = "yes"])
+AM_CONDITIONAL([ENABLE_RESUME_STATIC], [test "${enable_resume_static}" = "yes"])
+AM_CONDITIONAL([ENABLE_CREATE_DEVICE], [test "${enable_create_device}" = "yes"])
+AM_CONDITIONAL([ENABLE_SPLASHY], [test "${enable_splashy}" = "yes"])
+AC_CONFIG_FILES([
+	Makefile
+	doc/Makefile
+	scripts/Makefile
+	scripts/suse-10.1/Makefile
+])
+AC_OUTPUT
+
diff -urNp suspend.org/dmidecode.c suspend.x/dmidecode.c
--- suspend.org/dmidecode.c	2006-03-08 01:54:21.000000000 +0200
+++ suspend.x/dmidecode.c	2007-09-04 08:11:59.000000000 +0300
@@ -11,6 +11,7 @@
  *	Licensed under the GNU General Public license v2.
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <unistd.h>
 #include <fcntl.h>
diff -urNp suspend.org/doc/Makefile.am suspend.x/doc/Makefile.am
--- suspend.org/doc/Makefile.am	1970-01-01 02:00:00.000000000 +0200
+++ suspend.x/doc/Makefile.am	2007-09-04 08:11:59.000000000 +0300
@@ -0,0 +1,10 @@
+#
+# Makefile.am
+#
+# Copyright (C) 2007 Alon Bar-Lev <alon.barlev@gmail.com>
+#
+# This file is released under the GPLv2.
+#
+
+dist_noinst_DATA=installation-on-SUSE-10.1.txt
+
diff -urNp suspend.org/encrypt.c suspend.x/encrypt.c
--- suspend.org/encrypt.c	2006-09-14 17:18:58.000000000 +0300
+++ suspend.x/encrypt.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,8 @@
  *
  */
 
+#include "config.h"
+
 #ifdef CONFIG_ENCRYPT
 #include <sys/types.h>
 #include <sys/stat.h>
diff -urNp suspend.org/keygen.c suspend.x/keygen.c
--- suspend.org/keygen.c	2007-01-23 14:06:32.000000000 +0200
+++ suspend.x/keygen.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,7 @@
  *
  */
 
+#include "config.h"
 #include <sys/types.h>
 #include <sys/stat.h>
 #include <fcntl.h>
diff -urNp suspend.org/loglevel.c suspend.x/loglevel.c
--- suspend.org/loglevel.c	2007-01-25 14:56:17.000000000 +0200
+++ suspend.x/loglevel.c	2007-09-04 08:11:59.000000000 +0300
@@ -4,6 +4,7 @@
  * (c) 2007 Tim Dijkstra
  */
 
+#include "config.h"
 #include <unistd.h>
 #include <stdio.h>
 #include <errno.h>
diff -urNp suspend.org/Makefile suspend.x/Makefile
--- suspend.org/Makefile	2007-09-04 08:07:54.000000000 +0300
+++ suspend.x/Makefile	1970-01-01 02:00:00.000000000 +0200
@@ -1,157 +0,0 @@
-#CONFIG_COMPRESS=yes
-#CONFIG_ENCRYPT=yes
-#CONFIG_SPLASHY=yes
-#CONFIG_UDEV=yes
-#CONFIG_RESUME_DYN=yes
-
-PREFIX=/usr/local
-SUSPEND_DIR=$(PREFIX)/sbin
-RESUME_DIR=$(PREFIX)/lib/suspend
-CONFIG_DIR=/etc
-RESUME_DEVICE=<path_to_resume_device_file>
-BOOT_DIR=/boot
-CONFIGFILE=suspend.conf
-CFLAGS := -O2 -Wall
-
-###############################################################
-
-ARCH := $(shell uname -m | sed -e s/i.86/x86/ -e s/x86_64/x86/ -e s/ppc.*/ppc/)
-
-CC_FLAGS=-I/usr/local/include -DS2RAM $(CFLAGS)
-LD_FLAGS=-L/usr/local/lib
-
-BINARIES=s2disk s2both s2ram swap-offset resume
-BINARIES_MIN=s2disk swap-offset
-
-S2RAM_OBJ=vt.o config_parser.o
-SWSUSP_OBJ=vt.o md5.o encrypt.o config_parser.o loglevel.o splash.o bootsplash.o
-
-S2RAM_LD_FLAGS = $(LD_FLAGS)
-SWSUSP_LD_FLAGS = $(LD_FLAGS)
-ifeq ($(ARCH), x86)
-S2RAM_OBJ += s2ram-x86.o whitelist.o dmidecode.o radeontool.o vbetool/vbetool.o
-S2RAM_LD_FLAGS += -lx86 -lpci -lz
-endif
-ifeq ($(ARCH), ppc)
-S2RAM_OBJ += s2ram-ppc.o
-endif
-
-ifndef CONFIG_RESUME_DYN
-STATIC_LD_FLAGS = -static
-endif
-
-ifdef CONFIG_COMPRESS
-CC_FLAGS	+= -DCONFIG_COMPRESS
-SWSUSP_LD_FLAGS	+= -llzo2
-endif
-
-ifdef CONFIG_ENCRYPT
-BINARIES	+= suspend-keygen 
-BINARIES_MIN	+= suspend-keygen 
-CC_FLAGS	+= -DCONFIG_ENCRYPT
-GCRYPT_CC_FLAGS	= $(shell libgcrypt-config --cflags)
-SWSUSP_CC_FLAGS	+= $(GCRYPT_CC_FLAGS)
-GCRYPT_LD_FLAGS = $(shell libgcrypt-config --libs)
-SWSUSP_LD_FLAGS += $(GCRYPT_LD_FLAGS)
-INSTALL_KEYGEN	= install-keygen
-endif
-
-ifndef CONFIG_UDEV
-SNAPSHOT=$(DESTDIR)/dev/snapshot
-endif
-
-ifdef CONFIG_SPLASHY
-SWSUSP_OBJ	+= splashy_funcs.o 
-CC_FLAGS	+= -DCONFIG_SPLASHY
-SWSUSP_LD_FLAGS	+= -lsplashy
-ifndef CONFIG_RESUME_DYN
-STATIC_LD_FLAGS += -lsplashycnf \
-		$(shell directfb-config  --libs --input=keyboard \
-		--imageprovider=jpeg,gif,png\
-		--font=ft2,default) \
-		$(shell pkg-config --static --libs glib-2.0)
-STATIC_CC_FLAGS=$(shell directfb-config --cflags)\
-		$(shell pkg-config --static --cflags glib-2.0)
-else
-SWSUSP_LD_FLAGS += -lgcc_s
-endif
-endif
-
-
-
-all: $(BINARIES) 
-
-clean: 
-	rm -f $(BINARIES) suspend-keygen suspend.keys *.o vbetool/*.o
-
-#### Rules for objects
-s2ram-x86.o: %.o : %.c %.h
-	$(CC) $(CC_FLAGS) -c $< -o $@
-
-s2ram-both.o: s2ram.c s2ram.h
-	$(CC) $(CC_FLAGS) -DCONFIG_BOTH -c $< -o $@
-
-md5.o encrypt.o: %.o : %.c %.h md5.h
-	$(CC) $(CC_FLAGS) -DHAVE_INTTYPES_H -DHAVE_STDINT_H -c $< -o $@
-
-# Simple objects with header
-config_parser.o vt.o bootsplash.o splash.o splashy_funcs.o vbetool/vbetool.o s2ram-ppc.o: %.o : %.c %.h
-	$(CC) $(CC_FLAGS) -c $< -o $@
-
-# Simple object without header
-dmidecode.o radeontool.o : %.o: %.c
-	$(CC) $(CC_FLAGS) -c $< -o $@
-
-#### Rules for binaries
-s2disk:	$(SWSUSP_OBJ) suspend.c
-	$(CC) -g $(CC_FLAGS)  $^ -o $@ $(SWSUSP_LD_FLAGS)
-
-s2ram:	$(S2RAM_OBJ) s2ram.c s2ram-main.c
-	$(CC) -g $(CC_FLAGS) -include s2ram-$(ARCH).h $^ -o $@ $(S2RAM_LD_FLAGS)
-
-s2both:	$(SWSUSP_OBJ) $(S2RAM_OBJ) s2ram-both.o suspend.c 
-	$(CC) -g $(CC_FLAGS) -include s2ram-$(ARCH).h -DCONFIG_BOTH  $^ -o $@ $(SWSUSP_LD_FLAGS) $(S2RAM_LD_FLAGS)
-
-resume:	resume.c $(SWSUSP_OBJ)
-	$(CC) $(CC_FLAGS) $(STATIC_CC_FLAGS) $^ -o $@ $(SWSUSP_LD_FLAGS) $(STATIC_LD_FLAGS) 
-swap-offset: swap-offset.c
-	$(CC) $(CC_FLAGS) $< -o $@ $(LD_FLAGS)
-
-suspend-keygen:	 keygen.c md5.o encrypt.h 
-	$(CC) $(CC_FLAGS) $(GCRYPT_CC_FLAGS) -DHAVE_INTTYPES_H -DHAVE_STDINT_H md5.o $< -o $@ $(LD_FLAGS) $(GCRYPT_LD_FLAGS)
-
-
-
-
-#### Install targets
-$(SNAPSHOT):
-	mknod $(SNAPSHOT) c 10 231;
-
-install-conf: conf/$(CONFIGFILE)
-	if [ -f $(DESTDIR)$(CONFIG_DIR)/$(CONFIGFILE) ]; then \
-		install --mode=644 conf/$(CONFIGFILE) \
-			$(DESTDIR)$(CONFIG_DIR)/$(CONFIGFILE).new;\
-	else \
-		install -D --mode=644 conf/$(CONFIGFILE) \
-			$(DESTDIR)$(CONFIG_DIR)/$(CONFIGFILE); \
-	fi
-
-install-resume:
-	install -D --mode=755 resume $(DESTDIR)$(RESUME_DIR)/resume
-
-install-% : %
-	install -D --mode=755 $< $(DESTDIR)$(SUSPEND_DIR)/$<
-
-# Some convenience targets
-install-resume-new-initrd:	resume conf/$(CONFIGFILE)
-	BOOT_DIR=$(DESTDIR)$(BOOT_DIR) ./scripts/create-resume-initrd.sh $(RESUME_DEVICE)
-
-install-resume-on-initrd:	resume 
-	./scripts/install-resume.sh
-
-install-minimal: $(patsubst %,install-%,$(BINARIES_MIN)) $(SNAPSHOT) install-conf
-
-install: $(patsubst %,install-%,$(BINARIES)) $(SNAPSHOT) install-conf
-
-
-.PHONY: clean install install-minimal install-resume-on-initrd install-resume-new-initrd
diff -urNp suspend.org/Makefile.am suspend.x/Makefile.am
--- suspend.org/Makefile.am	1970-01-01 02:00:00.000000000 +0200
+++ suspend.x/Makefile.am	2007-09-04 08:11:59.000000000 +0300
@@ -0,0 +1,161 @@
+#
+# Makefile.am
+#
+# Copyright (C) 2007 Alon Bar-Lev <alon.barlev@gmail.com>
+#
+# This file is released under the GPLv2.
+#
+AUTOMAKE_OPTIONS=foreign dist-bzip2
+
+SUBDIRS=\
+	doc \
+	scripts
+noinst_LIBRARIES=\
+	libsuspend-common.a
+sbin_PROGRAMS=\
+	s2disk \
+	swap-offset
+dist_noinst_DATA= \
+	conf/suspend.conf
+sysconf_DATA=#required in order to create dir
+if !ENABLE_MINIMAL
+sbin_PROGRAMS+=\
+	s2ram \
+	s2both
+if ENABLE_ENCRYPT
+sbin_PROGRAMS+=\
+	suspend-keygen
+endif
+initramfs_PROGRAMS=\
+	resume
+dist_doc_DATA=\
+	TODO \
+	README* \
+	HOWTO \
+	COPYING*
+endif
+
+if ENABLE_CREATE_DEVICE
+dev_DATA=
+install-data-hook:
+	$(MKNOD) $(DESTDIR)$(devdir)/snapshot c 10 231
+endif
+
+install-data-local:
+	if [ -f $(DESTDIR)$(sysconfdir)/suspend.conf ]; then \
+		$(INSTALL_DATA) $(srcdir)/conf/suspend.conf $(DESTDIR)$(sysconfdir)/suspend.conf.new; \
+	else \
+		$(INSTALL_DATA) $(srcdir)/conf/suspend.conf $(DESTDIR)$(sysconfdir)/suspend.conf; \
+	fi
+
+AM_CFLAGS=\
+	-D_LARGEFILE64_SOURCE \
+	-DS2RAM \
+	$(LZO_CFLAGS) \
+	$(LIBGCRYPT_CFLAGS)
+
+common_s2disk_libs=\
+	$(LZO_LIBS) \
+	$(LIBGCRYPT_LIBS)
+common_s2ram_libs=
+
+if ENABLE_SPLASHY
+AM_CFLAGS+=\
+	${SPLASHY_CFLAGS}
+common_s2disk_libs+=\
+	${SPLASHY_LIBS}
+endif
+
+libsuspend_common_a_SOURCES=\
+	swsusp.h \
+	vt.h vt.c \
+	config_parser.h config_parser.c \
+	md5.h md5.c \
+	encrypt.h encrypt.c \
+	loglevel.h loglevel.c \
+	splash.h splash.c \
+	splashy_funcs.h splashy_funcs.c \
+	bootsplash.h bootsplash.c \
+	whitelist.h whitelist.c \
+	s2ram.h s2ram.c
+
+if ARCH_X86
+libsuspend_common_a_SOURCES+=\
+	s2ram-x86.h s2ram-x86.c \
+	dmidecode.c \
+	radeontool.c \
+	vbetool/vbetool.h vbetool/vbetool.c
+AM_CFLAGS+=\
+	$(LIBX86_CFLAGS) \
+	$(LIBPCI_CFLAGS)
+common_s2ram_libs+=\
+	$(LIBX86_LIBS) \
+	$(LIBPCI_LIBS)
+endif
+if ARCH_PPC
+libsuspend_common_a_SOURCES+=\
+	s2ram-ppc.h s2ram-ppc.c
+endif
+
+resume_CFLAGS=\
+	$(AM_CFLAGS) \
+	-D_GNU_SOURCE
+resume_SOURCES=\
+	resume.c
+resume_LDADD=\
+	libsuspend-common.a
+if ENABLE_RESUME_STATIC
+resume_LDADD+=\
+	$(common_s2disk_libs)
+resume_LDFLAGS=\
+	$(AM_LDFLAGS) \
+	-all-static
+else
+resume_LDADD+=\
+	$(common_s2disk_libs)
+endif
+
+s2disk_SOURCES=\
+	suspend.c
+s2disk_LDADD=\
+	libsuspend-common.a \
+	$(common_s2disk_libs)
+
+s2both_SOURCES=\
+	suspend.c
+s2both_CFLAGS=\
+	$(AM_CFLAGS) \
+	-DCONFIG_BOTH
+s2both_LDADD=\
+	libsuspend-common.a \
+	$(common_s2ram_libs) \
+	$(common_s2disk_libs)
+
+s2ram_SOURCES=\
+	s2ram-main.c
+s2ram_LDADD=\
+	libsuspend-common.a \
+	$(common_s2ram_libs)
+
+swap_offset_SOURCES=\
+	swap-offset.c
+
+suspend_keygen_SOURCES=\
+	keygen.c
+suspend_keygen_LDADD=\
+	libsuspend-common.a \
+	$(LIBGCRYPT_LIBS)
+
+#
+# Misc functions
+#
+install-resume-new-initrd:      resume
+	@if test -z "$(RESUME_DEVICE)"; then \
+		echo "Please specify --with-resume-device"; \
+		false; \
+	else \
+		BOOT_DIR=$(DESTDIR)$(bootdir) ./scripts/create-resume-initrd.sh $(RESUME_DEVICE); \
+	fi
+
+install-resume-on-initrd:       resume
+	BOOT_DIR=$(DESTDIR)$(bootdir) ./scripts/install-resume.sh
diff -urNp suspend.org/radeontool.c suspend.x/radeontool.c
--- suspend.org/radeontool.c	2006-03-15 16:18:33.000000000 +0200
+++ suspend.x/radeontool.c	2007-09-04 08:11:59.000000000 +0300
@@ -17,6 +17,7 @@
  *                                  by Stefan Seyfried <seife@suse.de>
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <stdlib.h>
 #include <unistd.h>
diff -urNp suspend.org/resume.c suspend.x/resume.c
--- suspend.org/resume.c	2007-09-04 08:07:54.000000000 +0300
+++ suspend.x/resume.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,9 +9,7 @@
  *
  */
 
-#define _GNU_SOURCE
-#define _LARGEFILE64_SOURCE
-
+#include "config.h"
 #include <sys/types.h>
 #include <sys/stat.h>
 #include <sys/ioctl.h>
diff -urNp suspend.org/s2ram.c suspend.x/s2ram.c
--- suspend.org/s2ram.c	2007-08-16 23:31:19.000000000 +0300
+++ suspend.x/s2ram.c	2007-09-04 08:11:59.000000000 +0300
@@ -5,6 +5,7 @@
  * Distribute under GPLv2.
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <stdlib.h>
 #include <getopt.h>
diff -urNp suspend.org/s2ram.h suspend.x/s2ram.h
--- suspend.org/s2ram.h	2007-06-17 23:51:30.000000000 +0300
+++ suspend.x/s2ram.h	2007-09-04 08:11:55.000000000 +0300
@@ -5,6 +5,13 @@
  * Distribute under GPLv2.
  */
 
+#ifdef CONFIG_ARCH_X86
+#include "s2ram-x86.h"
+#endif
+#ifdef CONFIG_ARCH_PPC
+#include "s2ram-ppc.h"
+#endif
+
 /* from radeontool.c */
 void radeon_cmd_light(int);
 void map_radeon_cntl_mem(void);
diff -urNp suspend.org/s2ram-main.c suspend.x/s2ram-main.c
--- suspend.org/s2ram-main.c	2007-08-15 19:56:07.000000000 +0300
+++ suspend.x/s2ram-main.c	2007-09-04 08:11:59.000000000 +0300
@@ -5,6 +5,7 @@
  * Distribute under GPLv2.
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <stdlib.h>
 #include <getopt.h>
diff -urNp suspend.org/s2ram-ppc.c suspend.x/s2ram-ppc.c
--- suspend.org/s2ram-ppc.c	2007-06-17 23:51:30.000000000 +0300
+++ suspend.x/s2ram-ppc.c	2007-09-04 08:11:59.000000000 +0300
@@ -6,6 +6,7 @@
  * Distribute under GPLv2.
  */
 
+#include "config.h"
 #include <errno.h>
 #include <fcntl.h>
 #include <unistd.h>
diff -urNp suspend.org/s2ram-x86.c suspend.x/s2ram-x86.c
--- suspend.org/s2ram-x86.c	2007-08-16 23:31:19.000000000 +0300
+++ suspend.x/s2ram-x86.c	2007-09-04 08:11:59.000000000 +0300
@@ -6,6 +6,7 @@
  * Distribute under GPLv2.
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <stdlib.h>
 #include <errno.h>
diff -urNp suspend.org/scripts/Makefile.am suspend.x/scripts/Makefile.am
--- suspend.org/scripts/Makefile.am	1970-01-01 02:00:00.000000000 +0200
+++ suspend.x/scripts/Makefile.am	2007-09-04 08:11:59.000000000 +0300
@@ -0,0 +1,14 @@
+#
+# Makefile.am
+#
+# Copyright (C) 2007 Alon Bar-Lev <alon.barlev@gmail.com>
+#
+# This file is released under the GPLv2.
+#
+
+SUBDIRS=\
+	suse-10.1
+
+dist_noinst_SCRIPTS=\
+	create-resume-initrd.sh \
+	install-resume.sh
diff -urNp suspend.org/scripts/suse-10.1/Makefile.am suspend.x/scripts/suse-10.1/Makefile.am
--- suspend.org/scripts/suse-10.1/Makefile.am	1970-01-01 02:00:00.000000000 +0200
+++ suspend.x/scripts/suse-10.1/Makefile.am	2007-09-04 08:11:59.000000000 +0300
@@ -0,0 +1,14 @@
+#
+# Makefile.am
+#
+# Copyright (C) 2007 Alon Bar-Lev <alon.barlev@gmail.com>
+#
+# This file is released under the GPLv2.
+#
+
+dist_noinst_SCRIPTS=\
+	modify-system-files.sh
+
+dist_noinst_DATA=\
+	do_acpi_sleep.patch \
+	mkinitrd.patch
diff -urNp suspend.org/splash.c suspend.x/splash.c
--- suspend.org/splash.c	2007-09-04 08:07:54.000000000 +0300
+++ suspend.x/splash.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,7 @@
  *
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <stdlib.h>
 #include <unistd.h>
diff -urNp suspend.org/splashy_funcs.c suspend.x/splashy_funcs.c
--- suspend.org/splashy_funcs.c	2007-05-12 23:37:47.000000000 +0300
+++ suspend.x/splashy_funcs.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,8 @@
  *
  */
 
+#include "config.h"
+
 #ifdef CONFIG_SPLASHY
 #include <string.h>
 #include <stdio.h>
diff -urNp suspend.org/suspend.c suspend.x/suspend.c
--- suspend.org/suspend.c	2007-09-04 08:07:55.000000000 +0300
+++ suspend.x/suspend.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,8 +9,7 @@
  *
  */
 
-#define _LARGEFILE64_SOURCE
-
+#include "config.h"
 #include <sys/types.h>
 #include <sys/stat.h>
 #include <sys/ioctl.h>
diff -urNp suspend.org/swap-offset.c suspend.x/swap-offset.c
--- suspend.org/swap-offset.c	2007-08-06 13:47:51.000000000 +0300
+++ suspend.x/swap-offset.c	2007-09-04 08:11:59.000000000 +0300
@@ -9,6 +9,7 @@
  *
  */
 
+#include "config.h"
 #include <stdio.h>
 #include <string.h>
 #include <fcntl.h>
diff -urNp suspend.org/vt.c suspend.x/vt.c
--- suspend.org/vt.c	2006-03-16 23:19:01.000000000 +0200
+++ suspend.x/vt.c	2007-09-04 08:11:59.000000000 +0300
@@ -6,6 +6,7 @@
  * (C) 2006 Stefan Seyfried <seife@suse.de>
  */
 
+#include "config.h"
 #include <unistd.h>
 #include <sys/ioctl.h>
 #include <sys/kd.h>
diff -urNp suspend.org/whitelist.c suspend.x/whitelist.c
--- suspend.org/whitelist.c	2007-08-25 00:40:04.000000000 +0300
+++ suspend.x/whitelist.c	2007-09-04 08:11:59.000000000 +0300
@@ -3,6 +3,7 @@
  * and all the workarounds
  */
 
+#include "config.h"
 #include <stdlib.h>
 #include "whitelist.h"