updated oneko ebuild

oneko-1.2.ebuild (text/plain), 1.44 KB, created by Joshua Rich on 2007-09-01 10:39:06 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="A cat, dog and others which chase the mouse or windows around the screen"
HOMEPAGE="http://www.daidouji.com/oneko/"
SRC_URI="http://www.daidouji.com/oneko/distfiles/oneko-${PV}.sakura.5.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND="x11-libs/libX11
	x11-libs/libXext"
DEPEND="${RDEPEND}
	x11-misc/gccmakedep
	x11-misc/imake
	app-text/rman
	x11-proto/xextproto"

S="${WORKDIR}/oneko-${PV}.sakura.5"

src_unpack() {
	unpack "${A}"
	cd "${S}"
	epatch "${FILESDIR}/${PN}-nobsd.patch"
}

src_compile() {
	cd ${S}
	xmkmf -a || die "running xmkmf failed!"
	emake CDEBUGFLAGS="${CFLAGS}" CC="$(tc-getCC)" || die "make failed!"
}

src_install() {
	into /usr
	dobin oneko
	mv oneko._man oneko.1x
	doman oneko.1x
	dodoc README README-NEW README-SUPP
	make_desktop_entry "oneko" "oneko (cat)" "${FILESDIR}/cat.png" "Game;Amusement"
	make_desktop_entry "oneko -dog" "oneko (dog)" "${FILESDIR}/dog.png" "Game;Amusement"
	make_desktop_entry "killall -TERM oneko" "oneko kill" "" "Game;Amusement"
}

pkg_postinst() {
	elog "To kill oneko, type the following in a terminal:"
	elog ""
	elog "killall oneko"
	elog ""
	elog "If your mouse cursor changes to the default black cross"
	elog "after running ${PN}, you should emerge x11-apps/xsetroot"
	elog "and run:"
	elog ""
	elog "xsetroot -cursor_name left_ptr"
	elog ""
}