# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/viewvc/viewvc-1.0.4.ebuild,v 1.3 2007/08/19 12:29:05 phreak Exp $

inherit python eutils webapp

DESCRIPTION="ViewVC, a web interface to CVS and Subversion"
HOMEPAGE="http://viewvc.org/"
SRC_URI="http://viewvc.tigris.org/files/documents/3330/37319/${P}.tar.gz"

LICENSE="viewcvs"
KEYWORDS="~amd64 ~ppc sparc ~x86"
IUSE="cvs cvsgraph enscript highlight mod_python mysql subversion"

RDEPEND="
		cvs? (
			>=dev-lang/python-1.5.2
			app-text/rcs
		)

		subversion? (
			>=dev-lang/python-2.0
			>=dev-util/subversion-1.2.0
		)

		cvsgraph? ( >=dev-util/cvsgraph-1.5.0 )
		enscript? ( app-text/enscript )
		highlight? ( >=app-text/highlight-2.2.10 )
		mod_python? ( www-apache/mod_python )
		mysql? (
			>=dev-python/mysql-python-0.9.0
		)
"

pkg_setup() {
	webapp_pkg_setup
	if use subversion && ! built_with_use dev-util/subversion python ; then
		eerror "Your Subversion has been built without Python bindings"
		die "Emerge dev-util/subversion with USE=\"python\""
	fi

	if use mysql && !( use cvs || use subversion ) ; then
		eerror "mysql requires cvs and/or subversion"
		die "Add USE=\"cvs\" and/or USE=\"subversion\""
	fi
}

src_unpack() {
	unpack ${A} && cd ${S}

	python_version
	local LIB_DIR="/usr/$(get_libdir)/python${PYVER}/site-packages/${PN}"
	find bin -type f |
		xargs sed -ie "	s|\(^LIBRARY_DIR\)\(.*\$\)|\1 = \"${LIB_DIR}\"|g"
}

src_install() {
	webapp_src_preinst
	python_version

	local pydir="/usr/$(get_libdir)/python${PYVER}/site-packages/${PN}/"

	exeinto ${MY_CGIBINDIR}
	doexe bin/cgi/viewvc.cgi

	if use mysql ; then
		doexe bin/cgi/query.cgi

		dodir ${MY_HOSTROOTDIR}/bin
		exeinto ${MY_HOSTROOTDIR}/bin
		doexe bin/make-database

		if use cvs ; then
			doexe bin/cvsdbadmin
			doexe bin/loginfo-handler
		fi

		if use subversion ; then
			doexe bin/svndbadmin
		fi
	fi

	if use mod_python ; then
		insinto ${MY_HTDOCSDIR}
		doins bin/mod_python/viewvc.py
		doins bin/mod_python/handler.py
		doins bin/mod_python/.htaccess

		if use mysql ; then
			doins bin/mod_python/query.py
		fi
	fi

	dodir ${MY_HTDOCSDIR}/templates
	cp -rp templates/* ${D}/${MY_HTDOCSDIR}/templates

	insinto ${MY_HTDOCSDIR}
	insinto ${MY_ICONSDIR}

	dodir ${pydir}
	cp -rp lib/* ${D}/${pydir}

	insinto ${MY_HOSTROOTDIR}
	newins ${PN}.conf.dist ${PN}.conf
	webapp_configfile ${MY_HOSTROOTDIR}/${PN}.conf
	if use cvsgraph ; then
		newins cvsgraph.conf.dist cvsgraph.conf
		webapp_configfile ${MY_HOSTROOTDIR}/cvsgraph.conf
	fi

	dodoc CHANGES COMMITTERS INSTALL README TODO
	dohtml -r viewvc.org/*

	webapp_hook_script ${FILESDIR}/reconfig

	webapp_src_install
}

pkg_postinst() {
	python_version
	local pydir="/usr/$(get_libdir)/python${PYVER}/site-packages/${PN}/"
	python_mod_optimize "${ROOT}/${pydir}"

	local mansuffix=$(ecompress --suffix)
	elog "Now read /usr/share/doc/${P}/INSTALL${mansuffix} to configure ${PN}"
	webapp_pkg_postinst
}

pkg_postrm() {
	python_version
	python_mod_cleanup
}