inform-7.4x_p60.ebuild

inform-7.4x_p60.ebuild (text/plain), 2.63 KB, created by David Leverton on 2007-08-25 11:25:00 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV="4X60"

DESCRIPTION="design system for interactive fiction"
HOMEPAGE="http://www.inform-fiction.org/"
SRC_URI="x86? ( http://www.inform-fiction.org/I7Downloads/I7_${MY_PV}_Linux_i386.tar.gz )
	amd64? ( http://www.inform-fiction.org/I7Downloads/I7_${MY_PV}_Linux_i386.tar.gz )
	!x86? ( !amd64? ( http://www.inform-fiction.org/I7Downloads/I7_${MY_PV}_Linux_all.tar.gz ) )"

# "Inform" for the core, "GPL-2" for the i7 user-interface script
LICENSE="Inform GPL-2"
SLOT="7"
#KEYWORDS="-* ~amd64 ~arm ~ppc ~s390 ~x86"
KEYWORDS="~amd64"
IUSE=""

RESTRICT="strip"

DEPEND=""
RDEPEND="dev-lang/perl
	games-engines/frotz
	games-engines/glulxe"

S="${WORKDIR}/inform7-${MY_PV}"

src_unpack() {
	unpack ${A}
	cd ${S}

	mkdir usr
	cd usr

	case ${ARCH} in
		amd64) IARCH=i386     ;;
		arm)   IARCH=armv5tel ;;
		x86)   IARCH=i386     ;;
		*)     IARCH=${ARCH}
	esac

	tar xzf ${S}/inform7-common_${MY_PV}_all.tar.gz || die
	tar xzf ${S}/inform7-compilers_${MY_PV}_${IARCH}.tar.gz || die
	# We don't currently use anything from here, but a future version
	# might include more interpreters.
	tar xzf ${S}/inform7-interpreters_${MY_PV}_${IARCH}.tar.gz || die

	epatch "${FILESDIR}"/inform7-4U65-paths.patch

	# Don't use the bundled interpreter binaries.  We do, however,
	# keep the bundled Inform 6 compiler, because it has some
	# modifications to work with Inform 7-generated code.
	#
	# The binaries that we do keep are unpacked into /usr/share with
	# symlinks in /usr/libexec, which is silly; move them to libexec
	# (there doesn't seem to be any need to recreate the symlinks
	# going the other way: the i7 script accesses them from libexec).
	# List the kept binaries explicitly (instead of using a wildcard)
	# so that if a future version adds more, the rmdir will fail and
	# alert the maintainer that changes (new dependencies etc) might
	# be required.
	rm -f libexec/*
	mv share/inform7/Compilers/{ni,cBlorb,inform-6.31-biplatform} libexec || die
	rmdir share/inform7/Compilers || die
	rm share/inform7/Interpreters/{dumb-frotz,dumb-glulxe} || die
	rmdir share/inform7/Interpreters || die

	# It installs README and INSTALL to /usr/share/doc/inform7.  We
	# handle README in src_install, and there's no point installing
	# INSTALL at all.  Don't use rm -rf so that if a future version
	# adds more files, we'll get an error instead of silently removing
	# them.
	rm share/doc/inform7/README || die
	rm share/doc/inform7/INSTALL || die
	rmdir share/doc/inform7 || die
	rmdir share/doc || die
}

src_install() {
	cp -dpPR usr "${D}"
	dodoc README
}