quake3-openarena-0.7.1.ebuild

quake3-openarena-0.7.1.ebuild (text/plain), 1.42 KB, created by Paul Bredbury on 2007-08-15 18:23:27 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator games

MY_PV=$(delete_all_version_separators)

DESCRIPTION="Open-source replacement content for Quake 3 Arena, effectively creating a free stand-alone game"
HOMEPAGE="http://openarena.ws/"
SRC_URI="oa070.zip oa${MY_PV}-patch.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated smp"
RESTRICT="fetch strip"

RDEPEND="virtual/opengl
	media-libs/openal
	media-libs/libsdl
	x11-libs/libXext
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp"
DEPEND="app-arch/unzip"

S=${WORKDIR}/openarena-0.7.0

pkg_nofetch() {
	einfo "Please download ${SRC_URI} from:"
	einfo "  ${HOMEPAGE}"
	einfo "and move them to ${DISTDIR}"
	echo
}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${PN}

	local arch="i386" ded_exe="ioq3ded" exe="ioquake3" smp
	if use smp ; then
		smp="-smp"
	fi
	if use amd64 ; then
		arch="x86_64"
	fi

	ded_exe="${ded_exe}.${arch}"
	exe="${exe}${smp}.${arch}"

	exeinto "${dir}"
	doexe "${exe}" || die
	if use dedicated ; then
		doexe "${ded_exe}" || die
		games_make_wrapper ${PN}-ded "./${ded_exe}" "${dir}"
	fi

	insinto "${dir}"
	doins -r baseoa || die
	doins CHANGES CREDITS LINUXNOTES README || die

	games_make_wrapper ${PN} "./${exe}" "${dir}"
	# No icon is supplied, so use Quake 3's icon if available
	make_desktop_entry ${PN} "Quake III - Open Arena" quake3.png

	prepgamesdirs
}