# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-util/glbsp/glbsp-2.20.ebuild,v 1.1 2006/10/11 20:11:32 nyhm Exp $

inherit eutils toolchain-funcs versionator

MY_PV=$(delete_version_separator 1)
DESCRIPTION="A node builder specially designed for OpenGL ports of the DOOM game engine"
HOMEPAGE="http://glbsp.sourceforge.net/"
SRC_URI="mirror://sourceforge/glbsp/${PN}_src_${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="fltk"

DEPEND="sys-libs/zlib
	fltk? ( x11-libs/fltk )"

S="${WORKDIR}/${P}-source"

src_unpack() {
	unpack "${A}"
	cd "${S}"
	sed -i \
		-e "/^CC=/s:=.*:=$(tc-getCC):" \
		-e "/^CXX=/s:=.*:=$(tc-getCXX):" \
		-e "/^AR=/s:ar:$(tc-getAR):" \
		-e "/^RANLIB=/s:=.*:=$(tc-getRANLIB):" \
		-e "s:-O2:${CFLAGS}:" \
		-e "/STRIP/d" \
		Makefile.unx \
		|| die "sed Makefile.unx failed"
	sed -i \
		-e "/^CC=/s:=.*:=$(tc-getCC):" \
		-e "/^CXX=/s:=.*:=$(tc-getCXX):" \
		-e "s:-O -g3:${CFLAGS}:" \
		-e "/strip/d" \
		nodeview/Makefile.unx \
		|| die "sed nodeview Makefile failed"
}

src_compile() {
	emake -f Makefile.unx || die "emake glbsp failed"

	if use fltk ; then
		emake -f Makefile.unx glBSPX \
			FLTK_FLAGS="$(fltk-config --cflags)" \
			FLTK_LIBS="$(fltk-config --use-images --ldflags)" \
			|| die "emake glbspx failed"
		emake -f Makefile.unx -C nodeview \
			FLTK_CFLAGS="$(fltk-config --cflags)" \
			FLTK_LIBS="$(fltk-config --use-images --ldflags)" \
			|| die "emake nodeview failed"
	fi
}

src_install() {
	dobin "${PN}" || die "dobin failed"
	dolib.a "libglbsp.a" || die "dolib.a failed"
	doman "${PN}.1" || die "doman failed"
	dodoc "${PN}.txt" || die "dodoc failed"

	if use fltk ; then
		newbin glBSPX glbspx || die "newbin failed"
		newicon gui/icon.xpm glbspx.xpm || die "newicon failed"
		make_desktop_entry glbspx glBSPX glbspx.xpm

		dobin nodeview/nodeview || die "dobin failed"
		docinto nodeview
		dodoc nodeview/{README,TODO}.txt || die "dodoc failed"
	fi
}