# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/gnumeric/gnumeric-1.7.1.ebuild,v 1.7 2006/09/05 20:53:09 tcort Exp $

inherit eutils flag-o-matic gnome2

DESCRIPTION="Gnumeric, the GNOME Spreadsheet"
HOMEPAGE="http://www.gnome.org/projects/gnumeric/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 hppa ~ia64 ppc ppc64 sparc x86"
IUSE="gnome python static doc"

RDEPEND="sys-libs/zlib
	>=dev-libs/glib-2.6
	>=gnome-extra/libgsf-1.14.5
	>=x11-libs/goffice-0.4.2
	>=dev-libs/libxml2-2.4.12
	>=x11-libs/pango-1.8.1

	>=x11-libs/gtk+-2.10
	>=gnome-base/libglade-2.3.6
	>=gnome-base/libgnomeprint-2.8.2
	>=gnome-base/libgnomeprintui-2.8.2
	>=media-libs/libart_lgpl-2.3.11

	doc?   (
		>=x11-libs/libwnck-2.16.3
		>=x11-themes/gnome-themes-2.16.3
		>=gnome-extra/yelp-2.16.2 )
	gnome? (
		>=gnome-base/gconf-2
		>=gnome-base/libgnome-2
		>=gnome-base/libgnomeui-2
		>=gnome-base/libbonobo-2.2
		>=gnome-base/libbonoboui-2.2 )
	python? (
		>=dev-lang/python-2
		>=dev-python/pygtk-2 )"

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.29
	>=dev-util/pkgconfig-0.9
	app-text/scrollkeeper"

DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"

pkg_setup() {
	G2CONF="${G2CONF} \
		$(use_with gnome) \
		$(use_with python) \
		$(use_enable static)"

	if use gnome && ! built_with_use gnome-extra/libgsf gnome; then
		einfo "Please re-emerge gnome-extra/libgsf with the gnome USE flag set"
		die "gnome-extra/libgsf built without gnome support..."
	fi

	#gcc bug (http://bugs.gnome.org/show_bug.cgi?id=128834)
	replace-flags "-Os" "-O2"
}

src_unpack() {
	gnome2_src_unpack

	# Remove function redefinition
	epatch "${FILESDIR}"/${P}.patch
}