A slightly improved c-client ebuild

c-client-2002c.ebuild (text/plain), 1.38 KB, created by Wayne Davison on 2003-05-28 07:16:05 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

MY_PN=imap-2002c1
S=${WORKDIR}/${MY_PN}

DESCRIPTION="UW IMAP c-client library."
SRC_URI="ftp://ftp.cac.washington.edu/imap/${MY_PN}.tar.Z"
HOMEPAGE="http://www.washington.edu/imap/"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86 ~sparc ~ppc ~hppa ~alpha"
IUSE="ssl mbox"

PROVIDE="virtual/c-client"
DEPEND="!net-mail/vimap
	!net-mail/uw-imap
	virtual/glibc
	>=sys-libs/pam-0.72
	ssl? ( dev-libs/openssl )"

src_unpack() {
	unpack ${A}
	# Tarball packed with bad file perms
	chmod -R ug+w ${S} 

	cd ${S}/src/osdep/unix/
	cp Makefile Makefile.orig
	sed \
		-e 's,-g -fno-omit-frame-pointer -O6,${CFLAGS},g' \
		-e 's,SSLDIR=/usr/local/ssl,SSLDIR=/usr,g' \
		-e 's,SSLCERTS=$(SSLDIR)/certs,SSLCERTS=/etc/ssl/certs,g' \
		< Makefile.orig > Makefile
	cd ${S}
	#patch -p1 < ${FILESDIR}/Makefile.patch
}

src_compile() {
	if use ssl; then
		cd ${S}
		yes | make lnp SSLTYPE=unix || die
	else
		yes | make lnp SSLTYPE=none || die
	fi
}

src_install() {
	into /usr

	insinto /usr/include/imap
	doins c-client/{c-client,mail,imap4r1,rfc822,linkage,misc,smtp,nntp}.h
	doins c-client/{osdep,env_unix,env,fs,ftl,nl,tcp}.h
	dolib.a c-client/c-client.a
	dosym /usr/lib/c-client.a /usr/lib/libc-client.a

	dodoc CPYRIGHT README docs/*.txt docs/CONFIG docs/RELNOTES

	docinto rfc
	dodoc docs/rfc/*.txt
}