inherit autotools eutils


DESCRIPTION="2D multiple-robot simulator."
HOMEPAGE="http://playerstage.sourceforge.net/index.php?src=stage"
SRC_URI="http://surfnet.dl.sourceforge.net/sourceforge/playerstage/stage-${PV}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"

IUSE="doc"

DEPEND="
	>=x11-libs/gtk+-2.4
	>=sci-electronics/player-2.0.2
	x11-apps/rgb
	doc? (app-doc/doxygen)"

RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	if use doc; then
		epatch "${FILESDIR}/stage-2.0.3-docdst-fix.diff"
		eautoreconf || die "autoreconf failed"
	fi
}

src_compile() {
	#Disable gnome-canvas since its experimental
	econf --disable-gnomecanvas || die "configure failed"
	emake || die "make failed"
	
	if use doc; then
		cd docsrc
		doxygen -u stage.dox
		touch header.html
		emake "doc" || die "make doc failed"
		cd ..
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	if use doc; then
		cd docsrc
		emake DESTDIR="${D}" "doc-install" || die "make doc-install failed"
		cd ..
	fi

	dodoc AUTHORS ChangeLog NEWS README
}