# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/w32api/w32api-3.9.ebuild,v 1.2 2007/05/02 23:14:55 vapier Exp $

export CBUILD=${CBUILD:-${CHOST}}
export CTARGET=${CTARGET:-${CHOST}}
if [[ ${CTARGET} == ${CHOST} ]] ; then
	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
		export CTARGET=${CATEGORY/cross-}
	fi
fi

inherit eutils flag-o-matic

DESCRIPTION="Free Win32 runtime and import library definitions"
HOMEPAGE="http://www.mingw.org/"
SRC_URI="mirror://sourceforge/mingw/${P}-src.tar.gz 
         http://klehm.net/w32api-3.9-patches.tar.bz2"


LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE=""
RESTRICT="strip"

DEPEND=""

just_headers() {
	use crosscompile_opts_headers-only && [[ ${CHOST} != ${CTARGET} ]]
}

pkg_setup() {
	if [[ ${CBUILD} == ${CHOST} ]] && [[ ${CHOST} == ${CTARGET} ]] ; then
		die "Invalid configuration; do not emerge this directly"
	fi
}

src_unpack() {
	
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-3.7-DESTDIR.patch

	#start hans leidekker mingw header fixes
	ln -s "${S}" "${WORKDIR}"/${PN} || die "Could not make w32api symlink!!"
	PREV_EPATCH_OPTS="${EPATCH_OPTS}"
		EPATCH_OPTS="-d ${WORKDIR}"
		EPATCH_SOURCE="${WORKDIR}/${PN}-3.9-patches" EPATCH_SUFFIX="patch" \
		    EPATCH_FORCE="yes" epatch
	EPATCH_OPTS="${PREV_EPATCH_OPTS}"
	rm "${WORKDIR}"/${PN}
	#end hans leidekker mingw header fixes
}

src_compile() {
	just_headers && return 0

	CHOST=${CTARGET} strip-unsupported-flags
	econf \
		--host=${CTARGET} \
		--prefix=/usr/${CTARGET}/usr \
		|| die
	emake || die
}

src_install() {
	if just_headers ; then
		insinto /usr/${CTARGET}/usr/include
		doins -r include/* || die
	else
		emake install DESTDIR="${D}" || die
		env -uRESTRICT CHOST=${CTARGET} prepallstrip
		dodoc CONTRIBUTIONS ChangeLog README.w32api TODO
	fi
}