Ebuild for gelemental-1.0.0

gelemental-1.0.0.ebuild (text/plain), 1.15 KB, created by Kristian Poul Herkild on 2007-05-25 12:54:36 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit fdo-mime gnome2-utils

DESCRIPTION="A periodic table viewer with detailed information on elements."
HOMEPAGE="http://www.kdau.com/projects/gelemental/"
SRC_URI="http://www.kdau.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="ppc x86"
IUSE="debug doc python"

RDEPEND=">=dev-cpp/glibmm-2.6.0
	>=dev-cpp/gtkmm-2.6.0
	>=dev-util/pkgconfig-0.12
	virtual/libintl"

DEPEND="${RDEPEND}
	sys-devel/libtool
	sys-devel/gettext
	>=dev-util/intltool-0.35
	doc? ( app-doc/doxygen )"

PDEPEND="python? ( sci-chemistry/pygelemental )"

src_compile() {
	econf \
		$(use_enable debug) \
		$(use_enable doc api-docs) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make \
		DESTDIR="${D}" \
		apidir=/usr/share/doc/${PF}/html \
		install \
		|| die "install failed"
	dodoc README AUTHORS TRANSLATORS ChangeLog NEWS NEWS-GPeriodic TODO
	newdoc po/README README.translation
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}