# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/libmilter/libmilter-8.13.7.ebuild,v 1.2 2006/07/15 21:44:20 langthang Exp $

inherit eutils

MY_PN="sendmail"

DESCRIPTION="The Sendmail Filter API (Milter)"
HOMEPAGE="http://www.sendmail.org/"
SRC_URI="ftp://ftp.sendmail.org/pub/sendmail/sendmail.${PV}.tar.gz"

LICENSE="Sendmail"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="ipv6"

DEPEND=""
RDEPEND="${DEPEND}"

MY_SRC=sendmail
S="${WORKDIR}/${MY_SRC}-${PV}"

src_unpack() {
	unpack ${A}
	cd ${S}

	confCCOPTS="${CFLAGS}"
	confENVDEF=""
	use ipv6 && confENVDEF="${confENVDEF} -DNETINET6"
	sed -e "s:@@confCCOPTS@@:${confCCOPTS}:" \
		-e "s/@@confENVDEF@@/${confENVDEF}/" \
		"${FILESDIR}"/site.config.m4 > ${S}/devtools/Site/site.config.m4
}

src_compile() {
	pushd libmilter
	sh Build || die "libmilter compilation failed"
	popd
}

src_install () {
	OBJDIR="obj.`uname -s`.`uname -r`.`arch`"
	dodir /usr/lib
	dodir /usr/include/libmilter
		make DESTDIR=${D} MANROOT=/usr/share/man/man \
			SBINOWN=root SBINGRP=root UBINOWN=root UBINGRP=root \
			MANOWN=root MANGRP=root INCOWN=root INCGRP=root \
			LIBOWN=root LIBGRP=root GBINOWN=root GBINGRP=root \
			MSPQOWN=root CFOWN=root CFGRP=root \
			install -C ${OBJDIR}/libmilter \
			|| die "install failed"

	newdoc libmilter/README README.libmilter
}