xfoil-6.96.ebuild

xfoil-6.96.ebuild (text/plain), 1.85 KB, created by Sébastien Fabbro (RETIRED) on 2007-05-06 17:36:06 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs fortran

DESCRIPTION="Design and analysis of subsonic isolated airfoils"
HOMEPAGE="http://raphael.mit.edu/xfoil/"
SRC_URI="http://web.mit.edu/drela/Public/web/${PN}/${PN}${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~ppc"
IUSE=""

DEPEND="|| ( x11-libs/libX11 virtual/x11 )"

S=${WORKDIR}/Xfoil

src_unpack() {
	unpack ${A}
	cd "${S}"
	[ -z "${FFLAGS}" ] && FFLAGS="${CFLAGS}"

	# As defined in toolchain-funcs.eclass
	echo "CC = $(tc-getCC)" >> plotlib/config.make

	# As defined in fortran.eclass
	echo "FC = ${FORTRANC}" >> plotlib/config.make
	
	echo "CFLAGS += ${CFLAGS}" >> plotlib/config.make
	echo "FFLAGS += ${FFLAGS}" >> plotlib/config.make

	sed -i \
		-e "s/^\(FC.*\)/FC = ${FORTRANC}/g" \
		-e "s/^\(CC.*\)/CC = $(tc-getCC)/g" \
		-e "s/^\(FFLAGS .*\)/FFLAGS = ${FFLAGS}/g" \
		-e "s/^\(FFLOPT .*\)/FFLOPT = \$(FFLAGS)/g" \
		-e "s/^\(FFLAGS2 .*\)/FFLAGS2 = \$(FFLAGS)/g" \
		bin/Makefile orrs/bin/Makefile || die "sed failed"
	
	# fix bug #147033
	[[ "${FORTRANC}" == "gfortran" ]] && epatch "${FILESDIR}"/${P}-gfortran.patch

	# make everything double precision
	sed -i \
		-e 's:/var/local/codes/orrs/osmap.dat:/usr/share/xfoil/orrs/osmap.dat:' \
		-e 's:REAL*4:REAL:g' \
		orrs/src/osmap.f || die "sed osmap.f failed"
}

src_compile() {
	cd "${S}"/orrs/bin
	emake FLG="${FFLAGS}" FTNLIB="" OS || die "failed to build orrs"
	cd "${S}"/plotlib
	emake DP="" || die "failed to build plotlib"
	cd "${S}"/bin
	for i in xfoil pplot pxplot; do
		emake CFLAGS="${CFLAGS} -DUNDERSCORE" ${i} || die "failed to build ${i}"
	done
}

src_install() {
	dobin bin/pplot bin/pxplot bin/xfoil || die "dobin failed"
	./bin/osgen osmaps_ns.lst
	insinto /usr/share/xfoil/orrs
	doins orrs/osm*
	dodoc *.txt README
	docinto runs
	dodoc runs/*
}