elfsh-0.65_rc1.ebuild

elfsh-0.65_rc1.ebuild (text/plain), 1.62 KB, created by Cédric TESSIER on 2007-05-05 19:03:41 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/elfsh/elfsh-0.65_rc1.ebuild,v 1.1 2006/03/04 06:13:22 vapier Exp $

inherit eutils toolchain-funcs

MY_PV=${PV/_/}
DESCRIPTION="scripting language to modify ELF binaries"
HOMEPAGE="http://elfsh.asgardlabs.org/"
SRC_URI="mirror://gentoo/elfsh-${MY_PV}.tgz"
#http://elfsh.asgardlabs.org/files/elfsh-${MY_PV}-portable.tgz

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-*"
IUSE="readline"

DEPEND=">=dev-libs/expat-1.95
	readline? ( sys-libs/readline )"

S=${WORKDIR}/${PN}-${MY_PV}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PV}-gentoo.patch
	sed -i \
		-e 's: -O2 : :g' \
		-e "s: -g3 : ${CFLAGS} :" \
		-e "/^LDFLAGS/s:=:=${LDFLAGS} :" \
		$(find -name Makefile) \
		|| die
}

src_compile() {
	local bits
	local myconf
	touch foo.c && $(tc-getCC) -c foo.c -o foo.o || die 
	case $(file foo.o) in
		*64-bit*)  bits=64;;
		*32-bit*)  bits=32;;
		*)         die "unknown bits: $(file foo.o)";;
	esac
	# not an autoconf script
	myconf="--enable-${bits}"
	$([[ ${bits} == "64" ]] && myconf="${myconf} --enable-m64") 
	if use readline ; then
		myconf="${myconf} --enable-readline"
	fi

	./configure ${myconf} \
		|| die

	# emacs does not have to be a requirement.	
	emake ETAGS=echo || die "emake failed"
	emake e2dbg ETAGS=echo || die "emake e2dbg failed"
}

src_install() {
	make install DESTDIR="${D}" || die "install failed"
	dodoc README.FIRST doc/AUTHOR doc/CREDITS doc/Changelog doc/*.txt
	doman doc/*.1
}

pkg_postinst() {
	einfo "elfsh libasm renamed in libasmelfsh to avoid conflicts" 
}