# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
DESCRIPTION="The GNU Bug Tracking System"
HOMEPAGE="http://www.gnu.org/software/gnats/"
SRC_URI="http://ftp.gnu.org/pub/gnu/gnats/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="kerberos minimal"

RDEPEND="kerberos? ( virtual/krb5 )"
DEPEND="${REDPEND}"

pkg_setup() {
	enewuser gnats
}

src_compile() {
	# we force use of awk over gawk for better embedded support
	AWK=awk econf $(use_with kerberos) \
		--sharedstatedir=/var/lib/gnats \
		--disable-dependency-tracking || \
		die "econf failed"
	if use minimal ; then
		# build user tools only
		(cd gnats && emake all-tools) || die "gnats emake failed"
		(cd send-pr && emake all-tools) || die "send-pr emake failed"
	else
		emake all || die "emake failed"
	fi
}

src_install() {
	if use minimal ; then
		dodir /usr/bin
		dodir /etc/gnats
		# install user tools only
		(cd gnats && emake DESTDIR=${D} install-tools) || \
			die "gnats emake install-tools failed"
		(cd send-pr && emake DESTDIR=${D} install-tools) || \
			die "emake send-pr failed"
	else
		emake DESTDIR=${D} install || die "emake install failed"
	fi
	# I have no idea where the gnats.el file comes from
	rm -f ${D}/gnats.el
}