an ebuild for the (not yet available 2.04 version)

mldonkey-2.04.ebuild (text/plain), 2.71 KB, created by Christian Loitsch on 2003-05-10 20:08:25 UTC

IUSE="gtk"

S="${WORKDIR}/${PN}"
MY_PV=${PV/_/}

DESCRIPTION="mldonkey is a new client to access the eDonkey network. It is written in Objective-Caml, and comes with its own GTK GUI, an HTTP interface and a telnet interface."
HOMEPAGE="http://savannah.nongnu.org/projects/mldonkey/"
SRC_URI="http://savannah.nongnu.org/download/${PN}/release-${MY_PV}/${PN}-${MY_PV}.sources.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"

DEPEND="gtk? ( >=lablgtk-1.2.3 )
	>=dev-lang/ocaml-3.06
	dev-lang/perl"

src_compile() {
	use gtk || export GTK_CONFIG="no"

	# the dirs are not (yet) used, but it doesn't hurt to specify them anyway
	econf \
		--sysconfdir=/etc/mldonkey \
		--sharedstatedir=/var/mldonkey \
		--localstatedir=/var/mldonkey \
		--enable-ocamlver=3.06

	emake || die
}

src_install() {
	for i in mlchat mlnet mlgui mlnet+gui mlguistarter mlim; do
		dobin $i
	done

	exeinto /etc/init.d/
	newexe ${FILESDIR}/${PF}.rc mldonkey

	insinto /etc/conf.d/
	newins ${FILESDIR}/${PF}.config mldonkey

	cd docs
	dodoc *.txt *.pdf *tex
	dohtml *.html
	insinto /usr/share/doc/${PF}/images
	doins images/*
	
	cd ${S}/distrib
	dodoc AUTHORS BUGS COPYING ChangeLog Developers.txt ed2k_links.txt \
		Readme.txt TODO 
	dohtml FAQ.html
	
	insinto /usr/share/doc/${PF}/scripts
	doins kill_mldonkey mldonkey_command mldonkey_previewer;

	insinto /usr/share/doc/${PF}/distrib
	doins directconnect.ini;

	
}

pkg_postinst() {
	einfo "Execute the following command:"
	einfo "ebuild /var/db/pkg/net-p2p/${P}/${P}.ebuild config"
	einfo "to create mldonkey user, mldonkey group and /home/mldonkey."
	einfo ""
	einfo "If you want to use the /etc/init.d/mldonkey startup script"
	einfo "but don't want to create an mldonkey user, edit:"
	einfo "/etc/conf.d/mldonkey"
	einfo ""
	einfo "You still have the possibility to start mldonkey the'old way':"
	einfo "To start mldonkey, copy the contents of \$doc/distrib in a"
	einfo "writable directory, and start mldonkey from there."
	einfo "Eg: cp everything to /home/user1/mldonkey"
	einfo "then: cd /home/user1/mldonkey && mldonkey >> mld.log &"
	einfo "You can do this inside a screen session."
}

pkg_config() {
	einfo "Create mldonkey group and user (if not existant)"
	if ! groupmod mldonkey; then
		groupadd mldonkey || die "problem adding group mldonkey"
	fi

	# usermod returns 2 on user-exists-but-no-flags-given
	usermod mldonkey &>/dev/null
	if [ $? != 2 ]; then
		useradd -g mldonkey -s /bin/false -d /home/mldonkey -c "mldonkey" mldonkey
		assert "problem adding user mldonkey"
	fi

	einfo "Please copy all files from: /usr/share/doc/${PF}/distrib/ into /home/mldonkey:"
	einfo "cp /usr/share/doc/${PF}/distrib/* /home/mldonkey"
	einfo ""
	einfo "You may then add mldonkey to your default runlevel:"
	einfo "rc-update add mldonkey default"
}