gnustep-base/gnustep-back-cairo/gnustep-back-cairo-0.12.0.ebuild

gnustep-back-cairo-0.12.0.ebuild (text/plain), 2.06 KB, created by Dmitry S. Kulyabov on 2007-04-23 05:24:07 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnustep

S=${WORKDIR}/gnustep-back-${PV}

DESCRIPTION="Cairo back-end component for the GNUstep GUI Library."

HOMEPAGE="http://www.gnustep.org"
SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/gnustep-back-${PV}.tar.gz"
KEYWORDS="~ppc x86 amd64 ~sparc ~alpha"
SLOT="0"
LICENSE="LGPL-2.1"

PROVIDE="virtual/gnustep-back"

IUSE="${IUSE} opengl xim doc glitz"
DEPEND="${GNUSTEP_CORE_DEPEND}
	gnustep-base/gnustep-make
	gnustep-base/gnustep-base
	gnustep-base/gnustep-gui
	|| (
		(
			x11-libs/libICE
			x11-libs/libSM
			x11-libs/libX11
			x11-libs/libXext
			x11-libs/libXi
			x11-libs/libXmu
			x11-libs/libXt
			x11-libs/libXft
			x11-libs/libXrender
		)
		(
			virtual/xft
			virtual/x11
		)
	)
	>=media-libs/freetype-2.1.9
	opengl? ( virtual/opengl virtual/glu )
	>=x11-libs/cairo-1.2.0"

RDEPEND="${DEPEND}
	${DEBUG_DEPEND}
	${DOC_RDEPEND}
	media-fonts/dejavu"

egnustep_install_domain "System"

src_unpack() {
	unpack ${A}
	cd ${S}

	# DejaVu font is successor of Bitstream Vera
	sed -i -e "s:BitstreamVeraSans-Roman:DejaVuSans:g" \
	    -e "s:BitstreamVeraSansMono-Roman:DejaVuSansMono:g" \
	    -e "s:BitstreamVeraSans-Bold:DejaVuSans-Bold:g" \
	    ${S}/Source/cairo/CairoFontEnumerator.m
	    
	echo "ADDITIONAL_INCLUDE_DIRS += `freetype-config --cflags`" >> ${S}/Source/cairo/GNUmakefile.preamble
}

src_compile() {
	egnustep_env

	use opengl && myconf="--enable-glx"
	myconf="$myconf `use_enable xim`"
	myconf="$myconf --enable-server=x11"
	myconf="$myconf --enable-graphics=cairo --with-name=cairo"
	myconf="$myconf `use_enable glitz`"
	
	econf $myconf || die "configure failed"

	egnustep_make
}

src_install() {
	egnustep_env

	gnustep_src_install
	cd ${S}
	mkdir -p ${D}/$(egnustep_system_root)/Library/Fonts
	cp -pPR Fonts/Helvetica.nfont ${D}/$(egnustep_system_root)/Library/Fonts
	rm -rf ${D}/$(egnustep_system_root)/var

	dosym $(egnustep_system_root)/Library/Bundles/libgnustep-cairo-011.bundle $(egnustep_system_root)/Library/Bundles/libgnustep-cairo.bundle 
}